xnconvert-1.76.ebuild

xnconvert-1.76.ebuild (text/plain), 2.50 KB, created by Wojciech Myrda on 2018-02-03 10:14:06 UTC

# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit eutils fdo-mime

DESCRIPTION="XnConvert is a powerful and free cross-platform batch image processor (standalone batch convert of XnViewMP)"
HOMEPAGE="http://www.xnview.com/"

MY_V=${PV/./}
SRC_URI="x86? ( http://download.xnview.com/old_versions/XnConvert-${MY_V}-linux.tgz )
	   amd64? ( http://download.xnview.com/old_versions/XnConvert-${MY_V}-linux-x64.tgz )"

SLOT="0"
LICENSE="freedist"
KEYWORDS="~x86 ~amd64"
IUSE="bundled-libs sensors"
REQUIRED_USE="bundled-libs? ( !sensors )"
RESTRICT="strip"

BUNDLED_LIBS="
libicudata.so	libicudata.so.56	libicudata.so.56.1
libicui18n.so	libicui18n.so.56	libicui18n.so.56.1
libicuio.so	libicuio.so.56		libicuio.so.56.1
libicule.so	libicule.so.56		libicule.so.56.1
libiculx.so	libiculx.so.56		libiculx.so.56.1
libicutest.so	libicutest.so.56	libicutest.so.56.1
libicutu.so	libicutu.so.56		libicutu.so.56.1
libicuuc.so	libicuuc.so.56		libicuuc.so.56.1
libQt5Core.so.5	libQt5Core.so.5.9.3
libQt5DBus.so.5	libQt5DBus.so.5.9.3
libQt5Gui.so.5	libQt5Gui.so.5.9.3
libQt5Network.so.5	libQt5Network.so.5.9.3
libQt5Sensors.so.5	libQt5Sensors.so.5.9.3
libQt5Svg.so.5		libQt5Svg.so.5.9.3
libQt5Widgets.so.5	libQt5Widgets.so.5.9.3
libQt5XcbQpa.so.5	libQt5XcbQpa.so.5.9.3
libQt5Xml.so.5		libQt5Xml.so.5.9.3
"

BUNDLED_LIBS_DEPEND="dev-qt/qtcore:5
	dev-qt/qtgui:5
	dev-qt/qtmultimedia:5[widgets]
	dev-qt/qtwidgets:5
	dev-qt/qtnetwork:5
	sensors? ( dev-qt/qtsensors:5 )
	dev-qt/qtsvg:5
	dev-qt/qtx11extras:5
	dev-qt/qtxml:5
	dev-qt/qtdbus:5
	dev-qt/qtwebkit:5
	dev-libs/icu"

RDEPEND=">=dev-libs/glib-2
	x11-libs/libX11
	x11-libs/libXi
	x11-libs/libXt
	!bundled-libs? ( ${BUNDLED_LIBS_DEPEND} )
	"
DEPEND=""

S="${WORKDIR}/XnConvert"

src_prepare() {
	default

	if ! use bundled-libs ; then
		einfo Removing bundled libraries
		for libname in ${BUNDLED_LIBS} ; do
			rm -rv "${S}"/lib/${libname} || die "Failed removing bundled ${libname}"
		done
	fi
}

src_install() {
	declare XNCONV_HOME=/opt/XnConvert

	# Install XnConvert in /opt
	dodir ${XNCONV_HOME%/*}
	mv "${S}" "${D}"${XNCONV_HOME} || die "Unable to install XnConvert folder"

	# Create /opt/bin/xnconvert
	dodir /opt/bin/
	dosym ${XNCONV_HOME}/xnconvert.sh /opt/bin/xnconvert

	# Install icon and .desktop for menu entry
	newicon "${D}"${XNCONV_HOME}/xnconvert.png ${PN}.png
	make_desktop_entry xnconvert XnConvert ${PN} "Graphics" || die "desktop file sed failed"
}

pkg_postinst(){
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
}