# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

MY_PN="boinc-cvs"
MY_PV="2005-01-25"

DESCRIPTION="The Berkeley Open Infrastructure for Network Computing"
HOMEPAGE="http://boinc.ssl.berkeley.edu/"
SRC_URI="${HOMEPAGE}source/nightly/${MY_PN}-${MY_PV}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="glut server X"
DEPEND=">=sys-devel/gcc-3.0.4
	>=sys-devel/autoconf-2.59
	>=sys-devel/automake-1.9.3
	server? ( >=dev-lang/python-2.2
		>=dev-db/mysql-3.23
		net-www/apache )
	X? ( >=x11-libs/wxGTK-2.4.2
		virtual/x11 )
	glut? ( virtual/glut )"
RDEPEND="sys-apps/baselayout"
S=${WORKDIR}/boinc
EXTRA_ECONF="--enable-client `use_enable server`"

src_unpack() {
	unpack ${A}
	#point to a proper mouse device
	sed -i "s:/dev/mouse:/dev/psaux:g" ${S}/client/hostinfo_unix.C
}

src_compile() {
	econf || die "could not configure"
	emake || die "emake failed"
}

src_install() {
	einstall || die "install failed"

	exeinto /etc/init.d
	newexe "${FILESDIR}/boinc.init.d" boinc
	insinto /etc/conf.d
	newins "${FILESDIR}/boinc.conf.d" boinc
	exeinto /var/lib/boinc
	doexe ${FILESDIR}/boincwrapper
}

pkg_preinst() {
	enewgroup boinc
	enewuser boinc -1 /bin/bash /var/lib/boinc boinc
}

pkg_postinst() {
	chown -R boinc:boinc /var/lib/boinc
}