gluegen-2.3.2.ebuild

gluegen-2.3.2.ebuild (text/plain), 1.87 KB, created by Fabio Rossi on 2018-01-23 23:28:31 UTC

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

JAVA_PKG_IUSE="doc source test"
WANT_ANT_TASKS="ant-antlr ant-contrib dev-java/cpptasks:0"

inherit java-pkg-2 java-ant-2

DESCRIPTION="Automatically generate the JNI code necessary to call C libraries"
HOMEPAGE="http://jogamp.org/gluegen/www/"
SRC_URI="https://github.com/sgothel/gluegen/archive/v${PV}.tar.gz -> ${P}.tar.gz
		https://github.com/sgothel/jcpp/archive/v${PV}.tar.gz -> jcpp-${PV}.tar.gz"

LICENSE="BSD"
SLOT="2.3"
KEYWORDS="~amd64 ~x86"
IUSE=""

COMMON_DEP="
	dev-java/ant-core:0
	dev-java/antlr:0
	dev-java/jsr305:0"
RDEPEND="${COMMON_DEP}
	>=virtual/jre-1.6"

DEPEND="${COMMON_DEP}
	>=virtual/jdk-1.6
	dev-java/cpptasks:0
	test? (
		dev-java/junit:4
		dev-java/ant-junit4
	)"

JAVA_ANT_REWRITE_CLASSPATH="yes"
EANT_BUILD_XML="make/build.xml"
EANT_BUILD_TARGET="all.no_junit"
EANT_DOC_TARGET=""
EANT_GENTOO_CLASSPATH="antlr,ant-core jsr305"
EANT_NEEDS_TOOLS="yes"
EANT_TEST_TARGET="junit.run"
EANT_TEST_GENTOO_CLASSPATH="${EANT_GENTOO_CLASSPATH},junit-4"
EANT_GENTOO_CLASSPATH_EXTRA="${S}/build/${PN}{,-rt}.jar"
EANT_EXTRA_ARGS="-Dc.strip.libraries=false"

PATCHES=(
	"${FILESDIR}"/${P}-dont-copy-jars.patch
	"${FILESDIR}"/${P}-dont-strip.patch
	"${FILESDIR}"/${P}-dont-test-archive.patch
	"${FILESDIR}"/${P}-no-static-libstdc++.patch
)

src_prepare() {
	default

	rm -rf make/lib

	java-ant_bsfix_files "${S}/make/build-test.xml"
	mv ${WORKDIR}/jcpp-${PV}/* ${WORKDIR}/${P}/jcpp/
	java-pkg_jarfrom jsr305
}

src_test() {
	EANT_TASKS="ant-junit4" java-pkg-2_src_test
}

src_install() {
	java-pkg_dojar build/${PN}{,-rt}.jar
	java-pkg_doso build/obj/*.so

	use doc && dohtml -r doc/manual
	use source && java-pkg_dosrc src/java/*

	# for building jogl
	insinto /usr/share/${PN}-${SLOT}/make
	doins -r make/*
	insinto /usr/share/${PN}-${SLOT}/build
	doins build/artifact.properties
}