# Copyright 1999-2002 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# Author Georgi Georgiev <chutz@chubaka.net>
# $Header: $

inherit cvs
ECVS_SERVER="cvs.xvid.org:/xvid"
ECVS_MODULE="xvidcore"
ECVS_OPTIONS="-dP"

S=${WORKDIR}/${ECVS_MODULE}

DESCRIPTION="XviD encoding library"
HOMEPAGE="http://www.xvid.org/"

RDEPEND=">=dev-lang/nasm-0.98.30"
DEPEND="${RDEPEND}"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="x86 ppc sparc"

src_unpack() {
	cvs_src_unpack
	cd ${S}/build/generic || die
	if use ppc; then
		sed -e "s:^CC:#CC:" \
			-e "s:^LIBDIR:#LIBDIR:" \
			-e "s:^CFLAGS +=:#CFLAGS +=:" \
			-e "s:^CFLAGS =:CFLAGS +=:" \
			Makefile.linuxppc > Makefile
	elif use x86; then
		sed -e "s:^LIBDIR:#LIBDIR:" \
			-e "s:^CFLAGS +=:#CFLAGS +=:" \
			-e "s:^#CFLAGS += -D:CFLAGS += -D:" \
			Makefile.linuxx86 > Makefile
	elif use sparc; then
		sed -e "s:^CC:#CC:" \
			-e "s:^CFLAGS = -fPIC -Wall -D:CFLAGS = -D:" \
			Makefile.sparc > Makefile
	fi
}

src_compile() {
	cd ${S}/build/generic
	emake || die
}

src_install() {
	dodoc authors.txt changelog.txt gpl.txt todo.txt
	use doc && dodoc CodingStyle doc/README doc/xvid-decoding.txt doc/xvid-encoder.txt
	dodir /usr/share/${PN}
	insinto /usr/share/${PN}
	doins examples/*

	dodir /usr/share/${PN}/ex1
	insinto /usr/share/${PN}/ex1
	doins examples/ex1/*

	dolib.so ${S}/build/generic/libxvidcore.so
	dolib.a  ${S}/build/generic/libxvidcore.a

	insinto /usr/include
	doins src/xvid.h src/divx4.h src/encoder.h src/decoder.h
}