hydrogen-9999.ebuild

hydrogen-9999.ebuild (text/plain), 1.90 KB, created by Samuel Bauer on 2017-12-19 21:25:10 UTC

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6
inherit eutils cmake-utils flag-o-matic git-r3

DESCRIPTION="Advanced drum machine"
HOMEPAGE="http://www.hydrogen-music.org/"
EGIT_REPO_URI="https://github.com/${PN}-music/${PN}"

LICENSE="GPL-2 ZLIB"
SLOT="0"
KEYWORDS="amd64 ppc ppc64 x86"
IUSE="alsa +archive jack ladspa lash osc oss portaudio pulseaudio"
REQUIRED_USE="lash? ( alsa )"

RDEPEND="dev-qt/qtgui:5 dev-qt/qtcore:5 dev-qt/qtxmlpatterns:5
	archive? ( app-arch/libarchive )
	!archive? ( >=dev-libs/libtar-1.2.11-r3 )
	>=media-libs/libsndfile-1.0.18
	alsa? ( media-libs/alsa-lib )
	jack? ( virtual/jack )
	osc? ( media-libs/liblo )
	ladspa? ( media-libs/liblrdf )
	lash? ( media-sound/lash )
	portaudio? ( media-libs/portaudio )
	pulseaudio? ( media-sound/pulseaudio )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	dev-util/cmake"

DOCS=( AUTHORS ChangeLog DEVELOPERS README.txt )

# test off by default but do not remove WANT_CPPUNIT
# NOTE: portmidi see #90614, not tested with 0.9.7
# NOTE: rubberband librubberband2 buggy -> OFF
src_prepare() {
	# FIXME: The -I/usr/include/raptor2 gets lost in middle of build
	# https://github.com/hydrogen-music/hydrogen/issues/342
	sed -i '222 ainclude_directories(${PC_LRDF_INCLUDE_DIRS})' CMakeLists.txt || die
	eapply_user
}

src_configure() {
	local mycmakeargs=(
		-DWANT_ALSA=$(usex alsa)
		-DWANT_CPPUNIT=OFF
		-DWANT_DEBUG=OFF
		-DWANT_JACK=$(usex jack)
		-DWANT_JACKSESSION=$(usex jack)
		-DWANT_LADSPA=$(usex ladspa)
		-DWANT_LASH=$(usex lash)
		-DWANT_LIBARCHIVE=$(usex archive)
		-DWANT_LRDF=$(usex ladspa)
		-DWANT_NSMSESSION=$(usex osc)
		-DWANT_OSS=$(usex oss)
		-DWANT_PORTAUDIO=$(usex portaudio)
		-DWANT_PORTMIDI=OFF
		-DWANT_PULSEAUDIO=$(usex pulseaudio)
		-DWANT_RUBBERBAND=OFF
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	dosym /usr/share/hydrogen/data/doc /usr/share/doc/${PF}/html
}