# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games eutils

DESCRIPTION="Robotron (of the '82 fame) goes badly acid. Forget about Phobia ;). Commercial."
HOMEPAGE="http://www.pompomgames.com/mutantstorm.htm"
SRC_URI="mutantstorm-linux-v11.tar.gz UpdateMutantStorm_1_39.tar.gz"

LICENSE="POMPOM"
SLOT="0"
KEYWORDS="-* ~x86"
IUSE="no-bundled-sdl"
RESTRICT="fetch"

DEPEND=""
RDEPEND="no-bundled-sdl? ( =media-libs/libsdl-1.2* )"

pkg_nofetch() {
	einfo "This excellent shooter is commercial closed-source."
	einfo "You will have to obtain mutantstorm-linux-v11.tar.gz"
	einfo "and put it in ${DISTDIR}. One way is to purchase the"
	einfo "game from its site. There might be other options listed there."
	einfo ""
	einfo "You will also need the patch available at"
	einfo "http://www.pompomgames.com/files/UpdateMutantStorm_1_39.tar.gz ."
}

pkg_setup() {
	check_license
	games_pkg_setup
}

src_unpack() {
	unpack ${A}
}

src_install() {
	dodir "${GAMES_PREFIX_OPT}/${PN}/missionpacks" "${GAMES_BINDIR}"

	cd "${WORKDIR}/mutantstorm-linux-v11"
	cp -R ../menu script styles ../readme.htm instructions.htm pompom README \
		"${D}/${GAMES_PREFIX_OPT}/${PN}"

	exeinto "${GAMES_PREFIX_OPT}/${PN}"
	doexe ../mutantstorm{,-bin}
	if ! useq no-bundled-sdl; then
		doexe bin/x86/libSDL*
		dosym libSDL-1.2.so.0.0.5 "${GAMES_PREFIX_OPT}/${PN}/libSDL-1.2.so.0"
	fi

	dosym "${GAMES_PREFIX_OPT}/${PN}/mutantstorm" "${GAMES_BINDIR}"

	prepgamesdirs
}