# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit games eutils

PACK="mutantstorm-linux-v11.tar.gz"

DESCRIPTION="Robotron (of the '82 fame) goes badly acid. Forget about Phobia ;)
. Commercial."

HOMEPAGE="http://www.pompomgames.com/mutantstorm.htm"
SRC_URI="${PACK}
UpdateMutantStorm_1_39.tar.gz"

LICENSE="POMPOM"
SLOT="0"
KEYWORDS="-* ~x86"
IUSE="bundled-sdl"
RESTRICT="fetch"

DEPEND=""
RDEPEND="!bundled-sdl? ( =media-libs/libsdl-1.2* )"

S="${WORKDIR}/mutantstorm-linux-v11"

pkg_nofetch() {
	einfo "This excellent shooter is commercial closed-source."
	einfo "You will have to obtain ${PACK} and put it in ${DISTDIR}."
	einfo "One way is to purchase the game from its site."
	einfo "There might be other options available listed there."
	einfo ""
	einfo "You will also need the patch available at"
	einfo "http://www.pompomgames.com/files/UpdateMutantStorm_1_39.tar.gz ."
}

pkg_setup() {
	check_license
}

src_unpack() {
	unpack ${A}
	cd ${S}
	mv ../mutantstorm{,-bin} bin/x86/
}

src_install() {
	local target="${GAMES_PREFIX_OPT}/${PN}"
	dodir "${target}/missionpacks" "${GAMES_BINDIR}"

	cd ${S}
	cp -R ../menu script styles ../readme.htm instructions.htm pompom README "${D}/${target}"

	exeinto "${target}"
	doexe bin/x86/mutant*

	if useq bundled-sdl; then
		doexe bin/x86/libSDL*
		ln -s libSDL-1.2.so.0.0.5 ${D}/${target}/libSDL-1.2.so.0
	fi

	ln -s ${target}/mutantstorm ${D}/${GAMES_BINDIR}

	prepgamesdirs
}

pkg_postinst() {
	if useq bundled-sdl; then
		ewarn "${P} has been installed with USE=\"bundled-sdl\", making the"
		ewarn "binary use use it's own version of libSDL-1.2.so.0. This was"
		ewarn "meant as a compatibility option only; if you notice any"
		ewarn "jerkiness, especially in the menu, try removing the USE flag."
	fi
}