ipmiview-2.13.0.170504.ebuild

ipmiview-2.13.0.170504.ebuild (text/plain), 2.53 KB, created by Conrad Kostecki on 2017-11-25 13:51:22 UTC

# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="6"

inherit eutils java-vm-2 versionator

MY_DATE="$(get_version_component_range 4)"
MY_PN="IPMIView"
MY_PV="$(get_version_component_range 1-3)"

DESCRIPTION="IPMIView is a GUI-based software application that allows administrators to manage multiple target systems through BMC."
HOMEPAGE="http://www.supermicro.com/"
SRC_URI="ftp://ftp.supermicro.com/utility/${MY_PN}/${MY_PN}_${MY_PV}_build.${MY_DATE}_bundleJRE_Linux_x64.tar.gz"

LICENSE="supermicro"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE="bundled-jre bundled-stunnel"

RESTRICT="installsources fetch mirror strip"

DEPEND="sys-libs/ncurses
	!bundled-jre? ( virtual/jre )
	!bundled-stunnel? ( net-misc/stunnel )"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_PN}_${MY_PV}_build.${MY_DATE}_bundleJRE_Linux_x64"

QA_PREBUILT="opt/smcipmitool/libjcurses.so opt/smcipmitool/BMCSecurity/linux/stunnel32"

pkg_nofetch() {
	elog "Please download ${A}"
	elog "from ${HOMEPAGE}SwDownload/UserInfo.aspx?sw=0&cat=IPMI"
	elog "and place this file in ${DISTDIR}"
}

src_install() {
	if ! use bundled-jre; then
		dosym ${JAVA_VM_SYSTEM} /opt/${PN}/jre
	else
		insinto /opt/${PN}/jre
		doins -r jre/*
	fi

	if ! use bundled-stunnel; then
		if use amd64; then
			dosym /usr/bin/stunnel /opt/${PN}/BMCSecurity/linux/stunnel64
		elif use x86; then
			dosym /usr/bin/stunnel /opt/${PN}/BMCSecurity/linux/stunnel32
		fi
	else
		insinto /opt/${PN}/BMCSecurity/linux
		if use amd64; then
			doins BMCSecurity/linux/stunnel64
		elif use x86; then
			doins BMCSecurity/linux/stunnel32
		fi
	fi

	dodoc *.pdf
	dodoc ReleaseNotes.txt

	insinto /opt/${PN}/BMCSecurity/linux
	doins BMCSecurity/linux/stunnel.conf

	insinto /opt/${PN}/BMCSecurity
	doins BMCSecurity/lockKey.txt
	doins BMCSecurity/mail.pem

	insinto /opt/${PN}
	doins *.jar
	if use amd64; then
		doins *64.jnilib
	elif use x86; then
		doins *32.jnilib
	fi
	doins *.lax
	if use amd64; then
		doins *64.so
	elif use x86; then
		doins *32.so
	fi

	exeinto /opt/${PN}
	doexe iKVM
	doexe ${MY_PN}20
	doexe JViewerX9
	doexe TrapReceiver

	dodir /opt/bin
	dosym ../${PN}/iKVM /opt/bin/ikvm
	dosym ../${PN}/${MY_PN}20 /opt/bin/${PN}
	dosym ../${PN}/JViewerX9 /opt/bin/jviewerx9
	dosym ../${PN}/TrapReceiver /opt/bin/trapreceiver

	doicon ${FILESDIR}/${PN}.ico
	doicon ${FILESDIR}/ipmitrap.ico

	make_desktop_entry ${PN} ${MY_PN} /usr/share/pixmaps/${PN}.ico Network Path=/opt/${PN}
	make_desktop_entry trapreceiver "Trap Receiver" /usr/share/pixmaps/ipmitrap.ico Network Path=/opt/${PN}
}