ipmicfg-1.27.1.170901.ebuild

ipmicfg-1.27.1.170901.ebuild (text/plain), 1.13 KB, created by Conrad Kostecki on 2017-11-25 13:50:21 UTC

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="6"

inherit versionator

MY_DATE="$(get_version_component_range 4)"
MY_PN="${PN^^}"
MY_PV="$(get_version_component_range 1-3)"

DESCRIPTION="IPMICFG is an in-band utility for configuring Supermicro IPMI devices"
HOMEPAGE="http://www.supermicro.com/"
SRC_URI="ftp://ftp.supermicro.com/utility/${MY_PN}/${MY_PN}_${MY_PV}_build.${MY_DATE}.zip"

LICENSE="supermicro"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"

RESTRICT="installsources fetch mirror strip"

S="${WORKDIR}/${MY_PN}_${MY_PV}_build.${MY_DATE}/Linux"

pkg_nofetch() {
	elog "Please download ${A}"
	elog "from ${HOMEPAGE}SwDownload/UserInfo.aspx?sw=0&cat=IPMI"
	elog "and place this file in ${DISTDIR}"
}

src_install() {
	if use amd64; then
		MY_ARCH_BINARY="x86_64"
		MY_ARCH_FOLDER="64bit"
	elif use x86; then
		MY_ARCH_BINARY="x86"
		MY_ARCH_FOLDER="32bit"
	fi

	insinto /opt/${PN}
	doins ${MY_ARCH_FOLDER}/*.dat

	exeinto /opt/${PN}
	doexe ${MY_ARCH_FOLDER}/${MY_PN}-Linux.${MY_ARCH_BINARY}

	dodir /opt/bin
	dosym ../${PN}/${MY_PN}-Linux.${MY_ARCH_BINARY} /opt/bin/${PN}
}