blitz-1.0.1.ebuild

blitz-1.0.1.ebuild (text/plain), 2.20 KB, created by Yann Leprince on 2017-11-22 17:22:05 UTC

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

PYTHON_COMPAT=( python2_7 )
inherit autotools multilib-build multilib-minimal python-any-r1

DESCRIPTION="High-performance C++ numeric library"
HOMEPAGE="https://github.com/blitzpp/blitz"
SRC_URI="https://github.com/blitzpp/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="|| ( LGPL-3 Artistic-2 BSD )"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~ppc-macos ~x86-linux ~x86-macos"

IUSE="boost -debug doc examples static-libs"

RDEPEND="boost? ( >=dev-libs/boost-1.40[${MULTILIB_USEDEP}] )"
DEPEND="${RDEPEND}
	${PYTHON_DEPS}
	doc? (
	app-doc/doxygen[dot]
	sys-apps/texinfo
	app-text/texi2html
)"

ECONF_SOURCE=${S}
MULTILIB_WRAPPED_HEADERS=(
	/usr/include/blitz/gnu/bzconfig.h
)

src_prepare() {
	(cd doc && eapply "${FILESDIR}/${PN}-0.10-docs.patch")
	# Fix error with newer Texinfo
	sed -i -e '/@setcontentsaftertitlepage/d' doc/blitz.texi || die
	eapply -p0 "${FILESDIR}/${PN}-0.10-set-default-arg-value.patch"
	eapply -p1 "${FILESDIR}/${PN}-1.0.1-fix-lib-reference.patch"
	eapply_user
	WANT_AUTOCONF=2.59 WANT_AUTOMAKE=1.9 eautoreconf
}

multilib_src_configure() {
	if multilib_is_native_abi && use doc; then
		doxygen -u "${S}"/doc/doxygen/Doxyfile.in || die "Failed to run Doxygen"
	fi
	# blas / fortran only needed for benchmarks
	econf \
		--enable-shared \
		$(use_enable static-libs static) \
		--disable-cxx-flags-preset \
		--disable-fortran \
		--without-blas \
		$(use_enable boost serialization) \
		$(use_enable debug) \
		$(use_enable doc doxygen) \
		$(use_enable doc html-docs) \
		$(use_with boost boost "${EPREFIX}/usr") \
		$(use_with boost boost-serialization)
}

multilib_src_compile() {
	emake lib
	if multilib_is_native_abi && use doc; then
		# The doc build has a race condition, so disable parallel build for now.
		emake -j1 info html pdf
	fi
}

multilib_src_test() {
	emake check-testsuite
}

multilib_src_install() {
	emake DESTDIR="${D}" install
	if multilib_is_native_abi && use doc; then
		emake DESTDIR="${D}" install-info install-html install-pdf
	fi
}

multilib_src_install_all() {
	einstalldocs
	if use examples; then
		insinto "/usr/share/doc/${PF}/examples"
		doins examples/*.{cpp,f}
	fi
}