net-wireless/unifi-5.6.19.ebuild

unifi-5.6.19.ebuild (text/plain), 1.36 KB, created by Conrad Kostecki on 2017-10-17 08:16:34 UTC

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI="6"

MY_PN="UniFi"
MY_PV="17e4cda571"

inherit multilib systemd user

DESCRIPTION="Management Controller for Ubiquiti Networks UniFi APs"
HOMEPAGE="https://www.ubnt.com"
SRC_URI="https://www.ubnt.com/downloads/unifi/${PV}-${MY_PV}/UniFi.unix.zip -> ${P}.zip"

LICENSE="UniFi-EULA"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="systemd"

DEPEND=""
RDEPEND="dev-db/mongodb
	virtual/jdk"

S="${WORKDIR}/${MY_PN}"

RESTRICT="bindist mirror preserve-libs"
QA_PREBUILT="*"

pkg_setup() {
	enewgroup ${PN}
	enewuser ${PN} -1 -1 /var/lib/${PN} ${PN}
}

src_install() {
	dodir /usr/$(get_libdir)/${PN}

	cp -R "${S}"/* "${D}"/usr/$(get_libdir)/${PN}

	keepdir /var/lib/${PN}/data
	dodir /var/lib/${PN}/run
	dodir /var/lib/${PN}/tmp
	dodir /var/lib/${PN}/work
	dodir /var/log/${PN}

	fowners -R ${PN}:${PN} /var/lib/unifi
	fowners -R ${PN}:${PN} /var/log/unifi

	dosym /var/lib/${PN}/data /usr/$(get_libdir)/${PN}/data
	dosym /var/lib/${PN}/run /usr/$(get_libdir)/${PN}/run
	dosym /var/lib/${PN}/work /usr/$(get_libdir)/${PN}/work
	dosym /var/log/${PN} /usr/$(get_libdir)/${PN}/logs

	echo 'CONFIG_PROTECT="/var/lib/unifi/data/system.properties"' > 99${PN}
	doenvd 99${PN}

	newinitd "${FILESDIR}/${PN}.initd" "${PN}"

	if use systemd; then
		systemd_dounit "${FILESDIR}/${PN}.service"
	fi
}