ebuild

tpm2-tss-1.2.0.ebuild (text/plain), 1.22 KB, created by Alex Guzman on 2017-10-15 04:11:38 UTC

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit linux-info

DESCRIPTION="TCG Trusted Platform Module 2.0 Software Stack"
HOMEPAGE="https://github.com/01org/tpm2-tss"
SRC_URI="https://github.com/01org/tpm2-tss/releases/download/${PV}/${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"

DEPEND="virtual/pkgconfig"

DOCS="AUTHORS"

pkg_setup() {
	linux-info_pkg_setup
	local tpm_kernel_version tpm_kernel_present
	kernel_is ge 4 12 0 && tpm_kernel_version="yes"
	if linux_config_exists; then
		linux_chkconfig_present TCG_TPM && tpm_kernel_present="yes"
	else
		ewarn "No kernel configuration could be found."
	fi
	if [[ -n "${tpm_kernel_present}" ]]; then
		einfo "Good, you seem to have in-kernel TPM support."
	elif [[ -n "${tpm_kernel_version}" ]]; then
		eerror
		eerror "To use this package, you will have to activate TPM support"
		eerror "in your kernel configuration. That's at least CONFIG_TCG_TPM,"
		eerror "plus probably a chip specific driver (like CONFIG_TCG_TIS)."
		eerror
	else
		eerror
		eerror "To use this package, you must install a kernel newer than"
		eerror "4.12.0 and enable TPM support."
		eerror
	fi
}

src_prepare() {
	default
	./bootstrap
}