moosefs-3.0.97.ebuild

moosefs-3.0.97.ebuild (text/plain), 1.78 KB, created by James Le Cuirot on 2017-10-09 20:03:31 UTC

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

PYTHON_COMPAT=( python2_7 )

inherit autotools python-single-r1 user

MY_P="moosefs-${PV}"
S="${WORKDIR}/${MY_P}"

DESCRIPTION="A filesystem for highly reliable petabyte storage"
HOMEPAGE="http://www.moosefs.org/"
SRC_URI="http://ppa.moosefs.com/src/moosefs-${PV}-1.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cgi +chunkserver client master"

REQUIRED_USE="${PYTHON_REQUIRED_USE}"

DEPEND="cgi? ( ${PYTHON_DEPS} )
	client? (
		net-libs/libpcap
		>=sys-fs/fuse-2.9
	)"

RDEPEND="${DEPEND}
	!sys-cluster/lizardfs"

PATCHES=( "${FILESDIR}/${PN}-cflags.patch" )

pkg_setup() {
	enewgroup mfs
	enewuser mfs -1 -1 -1 mfs
	python-single-r1_pkg_setup
}

src_prepare() {
	default

	# rename dist config files
	sed -i -e 's@\.sample@@g' mfsdata/Makefile.am || die "sed failed"

	eautoreconf
}

src_configure() {
	econf \
		--sysconfdir=/etc \
		--with-default-user=mfs \
		--with-default-group=mfs \
		$(use_enable client mfsmount)\
		$(use_enable client mfsnetdump)\
		$(use_enable cgi mfscgi) \
		$(use_enable cgi mfscgiserv) \
		$(use_enable chunkserver mfschunkserver) \
		$(use_enable master mfsmaster) \
		$(use_enable master mfsmetalogger)
}

src_install() {
	emake DESTDIR="${D}" install

	if use cgi; then
		python_fix_shebang "${D}"/usr/sbin/mfscgiserv
		newinitd "${FILESDIR}/moosefs-cgiserver.initd" mfs-cgiserver
		newconfd "${FILESDIR}/moosefs-cgiserver.confd" mfs-cgiserver
	fi

	local f
	for f in chunkserver master; do
		if use ${f}; then
			newinitd "${FILESDIR}/moosefs-${f}.initd" mfs-${f}
			newconfd "${FILESDIR}/moosefs-${f}.confd" mfs-${f}
		fi
	done

	if use master || use cgi || use chunkserver; then
		fowners -R mfs:mfs /var/lib/mfs
		fperms 750 /var/lib/mfs
	fi
}