GIMX 6.8 ebuild

gimx-6.8.ebuild (text/plain), 1.37 KB, created by BT on 2017-09-21 03:00:03 UTC

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

WX_GTK_VER="3.0"

inherit linux-info udev wxwidgets

MY_PN="GIMX"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="Control a video game console with a mouse, keyboard, or joystick"
HOMEPAGE="https://github.com/matlo/GIMX"
SRC_URI="https://github.com/matlo/${MY_PN}/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE=""

DEPEND="app-crypt/mhash
	dev-libs/libxml2
	net-misc/curl[ssl,curl_ssl_gnutls]
	net-wireless/bluez
	sys-devel/gettext
	sys-libs/ncurses:0/6
	virtual/libusb:1
	x11-libs/libX11
	x11-libs/libXi
	x11-libs/wxGTK:${WX_GTK_VER}[X]
"

RDEPEND="${DEPEND}
	x11-misc/xdg-utils
	x11-terms/xterm
"

S="${WORKDIR}/${MY_P}"

# only gimx links against the gimx libraries
QA_SONAME="/usr/lib.*/libgimx.*.so"

CONFIG_CHECK="~UHID"

DOCS=( README.md )

src_prepare() {
	default

	# install libraries in the correct lib directory
	sed -i -e "s:\$(exec_prefix)/lib:\$(exec_prefix)/$(get_libdir):" \
		shared/Makedefs || die 'sed failed!'
}

src_install() {
	default

	fowners root:input /usr/bin/gimx-{config,fpsconfig,launcher}
	fperms g+s /usr/bin/gimx-{config,fpsconfig,launcher}

	udev_dorules "${FILESDIR}"/99-gimx.rules
}

pkg_postinst() {
	udev_reload && udevadm trigger --sysname-match=uhid

	elog "To use GIMX you must be in the input group."
}