ebuild file

tinyos-1.1.0.ebuild (text/plain), 1.59 KB, created by Johannes Ballé on 2005-01-21 00:19:54 UTC

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

DESCRIPTION="An open-source OS designed for wireless embedded sensor networks"
HOMEPAGE="http://www.tinyos.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="INTEL-LICENSE"
SLOT="0"
KEYWORDS="~x86"
IUSE=""
DEPEND=""
RDEPEND="!dev-embedded/uisp"
PDEPEND="dev-embedded/nescc"

src_compile() {
	cd tools
	make prefix=/usr all || die "make all failed"
}

src_install() {
	# the build system of this package is very primitive.
	# correcting the mistakes afterwards (much less work)

	cd tools
	make prefix=${D}/usr install || die "make install failed"
	cd ${S}

	# correct man path
	mv ${D}/usr/man ${D}/usr/share/ \
		|| die "moving man files failed"

	# correct path for uisp docs & compress them
	dodir /usr/share/doc/${PF}
	mv ${D}/usr/share/doc/uisp* ${D}/usr/share/doc/${PF}/ \
		|| die "moving docs failed"
	prepalldocs

	dohtml -r -a html,jpg,JPG,gif,png,pdf,txt -x tex,schemadocsrc doc/*

	# make sure only regular files are in there
	if [ `find apps tos ! -type d ! -type f -printf x` ]; then
		die "non-regular files in apps or tos directory found!";
	fi

	# correct file modes
	chown -R root:root apps tos \
		&& find apps tos -type d ! -perm 755 -exec chmod 755 \{\} \; \
		&& find apps tos -type f ! -perm 644 -exec chmod 644 \{\} \; \
		|| die "correcting file modes failed"

	# install tos tree as-is, zip sample apps
	dodir /usr/share/tinyos
	mv tos ${D}/usr/share/tinyos/ || die "moving tos directory failed"
	tar -czf apps.tar.gz apps
	insinto /usr/share/tinyos
	doins apps.tar.gz
}