Possible ebuild

crossfire-client-1.72.0.ebuild (text/plain), 1.24 KB, created by Preston Crow on 2017-08-19 03:43:09 UTC

# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6
inherit vala cmake-utils toolchain-funcs gnome2-utils eutils

DESCRIPTION="Client for the nethack-style but more in the line of UO"
HOMEPAGE="http://crossfire.real-time.com/"
SRC_URI="mirror://sourceforge/crossfire/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="lua opengl sdl sound"

RDEPEND="
	lua? ( dev-lang/lua:0= )
	media-libs/libpng:0
	net-misc/curl
	opengl? ( virtual/opengl
		media-libs/freeglut )
	sdl? ( media-libs/libsdl[video]
		media-libs/sdl-image[png] )
	sound? ( media-libs/sdl-mixer[vorbis] )
	sys-libs/zlib
	x11-libs/gtk+:2
	dev-lang/vala"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

src_prepare() {
	default
	sed -i -e "s/valac-0.20/valac-0.36 valac-0.34 valac-0.32 valac-0.30 valac-0.28 valac-0.26/" cmake/FindVala.cmake || die
}

src_configure() {
	mycmakeargs=(
		-DLUA="$(usex lua)"
		-DSDL="$(usex sdl)"
		-DOPENGL="$(usex opengl)"
		-DSOUND="$(usex sound)"
		)
	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_make
}

src_install() {
	cmake-utils_src_install
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}