# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/dibbler/dibbler-0.3.1.ebuild,v 0.0 2004/06/24 23:41:39 thomson Exp $

inherit eutils

DESCRIPTION="Portable DHCPv6 implementation (server and client)"
HOMEPAGE="http://klub.com.pl/dhcpv6/"
SRC_URI="http://klub.com.pl/dhcpv6/${P}-src.tar.gz
		doc? ( http://klub.com.pl/dhcpv6/${P}-doc.tar.gz )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE="doc"
DEPEND=""

S=${WORKDIR}/${PN}
DIBBLER_DOCDIR=${WORKDIR}/doc

src_unpack() {
	unpack ${A}
	cd ${S}
	epatch ${FILESDIR}/${P}-security.patch

	sed -i -e 's:CLNTCONF_FILE.*:CLNTCONF_FILE "/etc/dibbler/client.conf":' \
		-e 's:SRVCONF_FILE.*:SRVCONF_FILE "/etc/dibbler/server.conf":' \
		${S}/misc/Portable.h || die "Failed to fix config file locations"
}

src_compile() {
	emake server client || die "Compilation failed"
}

src_install() {
	dosbin dibbler-server
	dosbin dibbler-client
	doman doc/man/dibbler-server.8 doc/man/dibbler-client.8
	dodoc CHANGELOG RELNOTES

	insinto /etc/dibbler
	doins *.conf

	use doc && dodoc ${DIBBLER_DOCDIR}/dibbler-user.pdf \
			${DIBBLER_DOCDIR}/dibbler-devel.pdf
}

pkg_postinst() {
	einfo "Make sure that you modify client.conf and/or server.conf to suit your needs."
	einfo "They are stored in /etc/dibbler."
}