bzflag-2.0.0.20050117.ebuild

bzflag-2.0.0.20050117.ebuild (text/plain), 1022 bytes, created by Andrew D. Keyser (aka Legoguy) on 2005-01-17 16:08:07 UTC

inherit flag-o-matic games

DESCRIPTION="OpenGL accelerated 3d tank combat simulator game"
HOMEPAGE="http://www.BZFlag.org/"
SRC_URI="mirror://sourceforge/bzflag/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc ~amd64"
IUSE="dedicated"

RDEPEND="virtual/libc
	!dedicated? ( virtual/opengl 
				  >=media-libs/libsdl-1.2.5 )"
DEPEND="${RDEPEND}
	>=sys-apps/sed-4"

src_unpack() {
	unpack ${A}
	cd ${S}
	sed -i \
		-e 's:^CFLAGS=.*::' \
		-e 's:^CXXFLAGS=.*::' \
		-e 's:-mcpu=$host_cpu::' \
		configure \
		|| die "sed failed"
	filter-flags -fno-default-inline
}

src_compile() {
	local myconf="--disable-dependency-tracking"

	if use dedicated ; then
		ewarn
		ewarn "You are building a servers-only copy of BZFlag."
		ewarn
		egamesconf ${myconf} --disable-client --without-SDL || die
	else
		egamesconf ${myconf} || die
	fi
	emake || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" install || die "make install failed"
	dodoc AUTHORS README.UNIX TODO README ChangeLog BUGS PORTING
	prepgamesdirs
}