ipsvd-0.9.7.ebuild

ipsvd-0.9.7.ebuild (text/plain), 1.15 KB, created by Torne Wuff on 2005-01-14 13:09:32 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit gcc

DESCRIPTION="ipsvd is a set of internet protocol service daemons for Unix."

HOMEPAGE="http://smarden.org/ipsvd/"
SRC_URI="http://smarden.org/ipsvd/${P}.tar.gz
		ssl? ( mirror://debian/pool/main/m/matrixssl/matrixssl_1.2.2.orig.tar.gz )"

LICENSE="BSD GPL-2"
SLOT="0"
KEYWORDS="~x86 ~ppc ~sparc ~mips ~alpha ~arm ~hppa ~amd64 ~ia64"

IUSE="static ssl"
DEPEND="virtual/glibc"

S=${WORKDIR}/net/${P}

src_unpack() {
	unpack ${P}.tar.gz
	cd ${S}
	
	use static && LDFLAGS="${LDFLAGS} -static"

	echo "$(gcc-getCC) ${CFLAGS}" > src/conf-cc
	echo "$(gcc-getCC) ${LDFLAGS}" > src/conf-ld
	if use ssl; then
	  unpack matrixssl_1.2.2.orig.tar.gz
	  mv matrixssl-1.2.2.orig/matrixssl-1-2-2.tar.gz src/matrixssl.tar.gz
	fi
}

src_compile() {
	cd ${S}/src
	emake || die "make failed"
}

src_install() {
	cd ${S}/src
	dobin tcpsvd udpsvd ipsvd-cdb
	use ssl && dobin sslio

	cd ${S}/package
	dodoc CHANGES README

	cd ${S}/doc
	dohtml *.html
	
	cd ${S}/man
	doman ipsvd-instruct.5 ipsvd.7 ipsvd-cdb.8 udpsvd.8 tcpsvd.8
	use ssl && doman sslio.8
}