pecl-pthreads-3.1.6.ebuild

pecl-pthreads-3.1.6.ebuild (text/plain), 894 bytes, created by Brian Evans (RETIRED) on 2017-07-07 16:35:10 UTC

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

USE_PHP="php5-6 php7-0 php7-1"

inherit php-ext-pecl-r3

USE_PHP="php7-0 php7-1"

KEYWORDS="~amd64 ~x86"

DESCRIPTION="Threading API for PHP"
LICENSE="PHP-3.01"
SLOT="7"
IUSE=""

DEPEND="
	php_targets_php7-0? ( dev-lang/php:7.0[threads] )
	php_targets_php7-1? ( dev-lang/php:7.1[threads] )
"
RDEPEND="${DEPEND} php_targets_php5-6? ( dev-php/pecl-pthreads:0[php_targets_php5-6] )"

src_prepare() {
	if use php_targets_php7-0 || use php_targets_php7-1 ; then
		php-ext-source-r3_src_prepare
	else
		eapply_user
	fi
}

src_configure() {
	if use php_targets_php7-0 || use php_targets_php7-1 ; then
		local PHP_EXT_ECONF_ARGS=( )
		php-ext-source-r3_src_configure
	fi
}

src_install() {
	if use php_targets_php7-0 || use php_targets_php7-1 ; then
		php-ext-pecl-r3_src_install
	fi
}