poppassd_ceti-1.8.4.ebuild

poppassd_ceti-1.8.4.ebuild (text/plain), 1.08 KB, created by Marcus D. Hanwell (RETIRED) on 2005-01-07 22:55:36 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils toolchain-funcs

MY_PN="poppassd"
MY_P="${MY_PN}-${PV}"
S=${WORKDIR}/${MY_P}

DESCRIPTION="POP Password Changer with PAM support"
HOMEPAGE="http://echelon.pl/pubs/poppassd.html"
SRC_URI="http://echelon.pl/pubs/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="cracklib"

DEPEND="virtual/libc
	>=sys-libs/pam-0.75-r8"

RDEPEND="${DEPEND}
	sys-apps/xinetd
	cracklib? ( sys-libs/cracklib )"

src_unpack() {
	unpack ${A}
	cd ${S}
	epatch ${FILESDIR}/gcc-fix.patch
}

src_compile() {
	$(tc-getCC) -c ${CFLAGS} ${MY_PN}.c || die "Compile failed."
	$(tc-getCC) -o poppassd ${MY_PN}.o -lpam -ldl || die "Linking failed."
}

src_install() {
	dodoc README

	insinto /etc/pam.d
	newins ${FILESDIR}/poppassd.pam poppassd
	use cracklib && sed -i -e 's|#password|password|' ${D}/etc/pam.d/poppassd

	insinto /etc/xinetd.d
	newins ${FILESDIR}/poppassd.xinetd poppassd

	insinto /usr/sbin
	insopts -o root -g bin -m 500
	doins poppassd || die "Install failed."
}