Partial Ebuild for 20160724

gnucap-0.35.20160724.ebuild (text/plain), 1.71 KB, created by maurerpe on 2017-06-23 02:31:36 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6

inherit multilib toolchain-funcs flag-o-matic

SNAPSHOTDATE="${P##*.}"
MY_PV="${PN}-${SNAPSHOTDATE}"

DESCRIPTION="GNUCap is the GNU Circuit Analysis Package"
SRC_URI="https://git.savannah.gnu.org/cgit/gnucap.git/snapshot/gnucap-${SNAPSHOTDATE}.tar.gz
	https://git.savannah.gnu.org/cgit/gnucap/gnucap-models.git/snapshot/gnucap-models-af119e0688b6c984103aca6ab544f246a5e6723b.tar.gz"
HOMEPAGE="http://www.gnucap.org/"

IUSE=""
SLOT="0"
LICENSE="GPL-2"
KEYWORDS=""

DEPEND=""
RDEPEND=""

S="${WORKDIR}/${MY_PV}"

src_prepare() {
	mv ../gnucap-models*/plugins/* .

	sed -i -e 's:CFLAGS = -O2 -g:CPPFLAGS +=:' \
		-e '/CCFLAGS =/i\CFLAGS += $(CPPFLAGS)' \
		-e 's:CCFLAGS = $(CFLAGS):CXXFLAGS += $(CPPFLAGS):' \
		-e 's:LDFLAGS = :LDFLAGS += :' \
		-e 's:CCFLAGS = :CXXFLAGS += :' \
		-e 's:CCFLAGS:CXXFLAGS:g' \
		models-*/Make2 || die "sed failed"

	sed -i -e 's:-O2::g' \
		-e 's:CCFLAGS =:CXXFLAGS +=:' \
		-e 's:CCFLAGS:CXXFLAGS:g' \
		-e 's:-lgnucap:-lgnucap -ldl:' \
		*/configure || die "sed failed"

	append-cxxflags $(test-flags-CXX '-std=gnu++98')

	tc-export CC CXX

	eapply_user
}

src_compile () {
	emake || die "Compilation failed"
	for PLUGIN_DIR in models-* ; do
		cd "${S}/${PLUGIN_DIR}"
		emake CC=$(tc-getCC) CCC=$(tc-getCXX) || die "Compilation failed in ${PLUGIN_DIR}"
	done
}

src_install () {
	emake DESTDIR="${D}" install || die "Installation failed"
	insopts -m0755
	for PLUGIN_DIR in models-* ; do
		insinto /usr/$(get_libdir)/gnucap/${PLUGIN_DIR}
		cd "${S}/${PLUGIN_DIR}"
		for PLUGIN in */*.so ; do
			newins ${PLUGIN} ${PLUGIN##*/} \
			|| die "Installation of ${PLUGIN_DIR}/${PLUGIN} failed"
		done
	done
}