games-rpg/daimonin-client-0.10.7.ebuild

daimonin-client-0.10.7.ebuild (text/plain), 1.66 KB, created by Simon on 2017-06-17 15:43:09 UTC

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=5
inherit eutils autotools games

MY_P=${PN}-${PV}
DESCRIPTION="a graphical 2D tile-based MMORPG"
HOMEPAGE="http://daimonin.sourceforge.net/"
SRC_URI="https://sourceforge.net/code-snapshots/svn/d/da/daimonin/code/daimonin-code-8168-trunk.zip
			-> daimonin-client-0.10.7.zip
		music? (
			!hifi? (
				https://downloads.sourceforge.net/project/daimonin/daimoninMusicLQ20100827.zip )
			hifi? (
				https://downloads.sourceforge.net/project/daimonin/daimoninMusicHQ20100827.zip ) )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ~ppc ~x86"
IUSE="debug music hifi"
REQUIRED_USE="hifi? ( music )"

RDEPEND="media-libs/libsdl[sound,video]
	media-libs/sdl-mixer[vorbis]
	media-libs/sdl-image[png]
	dev-games/physfs
	net-misc/curl"
DEPEND="${RDEPEND}
	app-arch/unzip"

S=${WORKDIR}/daimonin-code-8168-trunk/client/make/linux

src_unpack() {
	unpack ${MY_P}.zip
	if use music ; then
		cd daimonin-code-8168-trunk/client/media
		rm -f *
		cd ..
		if use hifi ; then
			unpack daimoninMusicHQ20100827.zip
		else
			unpack daimoninMusicLQ20100827.zip
		fi
	fi
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-nozlib.patch
	rm ../../src/include/z{lib,conf}.h
	sed -i \
		-e 's:$(d_datadir):$(DESTDIR)$(d_datadir):' \
		-e '/PROGRAMS/s:daimonin-updater::' \
		Makefile.am \
		|| die "sed failed"
	eautoreconf
	cd ../../src
        epatch "${FILESDIR}"/${P}-datadir.patch
}

src_configure() {
	egamesconf \
		--disable-simplelayout \
		$(use_enable debug)
}

src_install() {
	default
	cd ../..
	dodoc README*
	newicon bitmaps/pentagram.png ${PN}.png
	make_desktop_entry daimonin Daimonin
	prepgamesdirs
}