# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=6
inherit eutils toolchain-funcs

DESCRIPTION="A cat, dog and others which chase the mouse or windows around the screen"
HOMEPAGE="http://homepages.uni-paderborn.de/neuron/oneko/"
SRC_URI="http://homepages.uni-paderborn.de/neuron/oneko/${P}.txz
	http://homepages.uni-paderborn.de/neuron/oneko/oneko-kill-cat.png
	mirror://gentoo/oneko-1.2-cat.png
	mirror://gentoo/oneko-1.2-dog.png
	nobsd? ( mirror://gentoo/oneko-1.2-sakura-nobsd.patch.bz2 )"

LICENSE="public-domain"
SLOT="0"
KEYWORDS="amd64 ~ppc ~ppc64 ~x86"
IUSE="nobsd"
RDEPEND="
	x11-libs/libX11
	x11-libs/libXext
"
DEPEND="
	${RDEPEND}
	x11-misc/gccmakedep
	x11-misc/imake
	app-text/rman
	x11-proto/xextproto
    app-arch/tar
	app-arch/xz-utils
"

S=${WORKDIR}/oneko-${PV}

src_prepare() {
    eapply_user
    if use nobsd ; then
		epatch "${WORKDIR}"/oneko-1.2-sakura-nobsd.patch
	fi
}

src_configure() {
	xmkmf -a || die
}

src_compile() {
	emake \
		CC="$(tc-getCC)" \
		CCOPTIONS="${CFLAGS}" \
		EXTRA_LDOPTIONS="${LDFLAGS}" \
		|| die
}

src_install() {
	dobin oneko
	newman oneko._man oneko.1x
	dodoc README README-NEW README-SUPP
	newicon "${DISTDIR}/oneko-1.2-cat.png" "cat.png"
	newicon "${DISTDIR}/oneko-1.2-dog.png" "dog.png"
	newicon "${DISTDIR}/oneko-kill-cat.png" "kill_cat.png"
	make_desktop_entry "oneko" "oneko (cat)" "cat" "Game;Amusement"
	make_desktop_entry "oneko -dog" "oneko (dog)" "dog" "Game;Amusement"
	make_desktop_entry "killall -TERM oneko" "oneko kill" "kill_cat" "Game;Amusement"
}

pkg_postinst() {
	elog "To kill oneko, type the following in a terminal:"
	elog ""
	elog "killall oneko"
	elog ""
	elog "If your mouse cursor changes to the default black cross"
	elog "after running ${PN}, you should emerge x11-apps/xsetroot"
	elog "and run:"
	elog ""
	elog "xsetroot -cursor_name left_ptr"
	elog ""
}