moosefs-3.0.90.ebuild

moosefs-3.0.90.ebuild (text/plain), 1.87 KB, created by Marcin Mirosław on 2017-03-29 10:55:25 UTC

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI="5"

PYTHON_COMPAT=( python2_7 )

inherit autotools-utils eutils python-single-r1 user

MY_P="moosefs-${PV}"
S="${WORKDIR}/${MY_P}"

DESCRIPTION="A filesystem for highly reliable petabyte storage"
HOMEPAGE="http://www.moosefs.org/"
SRC_URI="http://ppa.moosefs.com/src/moosefs-${PV}-1.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cgi client +chunkserver master"

REQUIRED_USE="${PYTHON_REQUIRED_USE}"

RDEPEND="
	cgi? ( ${PYTHON_DEPS} )
	client? ( >=sys-fs/fuse-2.9 net-libs/libpcap )
	!sys-cluster/lizardfs"
DEPEND="${RDEPEND}"
PATCHES=( "${FILESDIR}/${PN}-cflags.patch" )
AUTOTOOLS_AUTORECONF="1"
AUTOTOOLS_IN_SOURCE_BUILD=1

pkg_setup() {
	enewgroup mfs
	enewuser mfs -1 -1 -1 mfs
	python-single-r1_pkg_setup
}

src_prepare() {
	# rename dist config files
	sed -i -e 's@\.sample@@g' mfsdata/Makefile.am || die "sed failed"
	autotools-utils_src_prepare
}

src_configure() {
	econf \
		--sysconfdir=/etc \
		--with-default-user=mfs \
		--with-default-group=mfs \
		$(use_enable client mfsmount)\
		$(use_enable client mfsnetdump)\
		$(use_enable cgi mfscgi) \
		$(use_enable cgi mfscgiserv) \
		$(use_enable chunkserver mfschunkserver) \
		$(use_enable master mfsmaster) \
		$(use_enable master mfsmetalogger)
}

src_install() {
	emake DESTDIR="${D}" install

	if use cgi; then
		python_fix_shebang "${D}"/usr/sbin/mfscgiserv
		newinitd "${FILESDIR}/moosefs-cgiserver.initd" mfs-cgiserver
		newconfd "${FILESDIR}/moosefs-cgiserver.confd" mfs-cgiserver
	fi
	local f
	for f in chunkserver master; do
		use ${f} && { newinitd "${FILESDIR}/moosefs-${f}.initd" mfs-${f}; newconfd "${FILESDIR}/moosefs-${f}.confd" mfs-${f}; }
	done

	if use master ||  use cgi || use chunkserver; then
		chown -R mfs:mfs "${D}/var/lib/mfs" || die
		chmod 750 "${D}/var/lib/mfs" || die || die
	fi
}