# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-action/tuxkart/tuxkart-0.4.0.ebuild,v 1.3 2004/10/31 05:06:58 vapier Exp $

inherit games

MY_P="${P}-1"
DESCRIPTION="A racing game starring Tux, the linux penguin (improved fork of TuxKart)"
HOMEPAGE="http://supertuxkart.berlios.de"
SRC_URI="http://download.berlios.de/${PN}/${MY_P}.tar.bz2"

S=${WORKDIR}/${MY_P}

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

RDEPEND=">=media-libs/plib-1.8.0
	>=media-libs/libsdl-1.2.4
	virtual/opengl"
DEPEND="${RDEPEND}
	>=sys-apps/sed-4"

src_unpack() {
	unpack ${A}
	cd ${S}

	sed -i \
		-e "/^bindir/s/=.*/=@bindir@/" src/Makefile.in \
		|| die "sed src/Makefile.in failed"
	sed -i \
		-e "/^pkgdata_DATA/s/\$/ \$(wildcard *.cup) \$(wildcard *.tkkf) \$(wildcard *.track)/" data/Makefile.in \
		|| die "sed data/Makefile.in failed"
	sed -i \
		-e "/^pkgdata_DATA/s/\$/ \$(wildcard *.tff)/" fonts/Makefile.in \
		|| die "sed fonts/Makefile.in failed"
	sed -i \
		-e "/^pkgdata_DATA/s/rgb/png/" images/Makefile.in \
		|| die "sed images/Makefile.in failed"
}

src_compile() {
	egamesconf --datadir="${GAMES_DATADIR_BASE}" || die
	emake || die "emake failed"
}

src_install() {
	make DESTDIR="${D}" install || die "make install failed"
	dodoc AUTHORS NEWS README
	dohtml ${D}/usr/share/supertuxkart/*.{html,png}
	rm -rf ${D}/usr/share/supertuxkart/

	prepgamesdirs
}