From 4a7554a24ffced5f4038e874b1cc418c07c4123b Mon Sep 17 00:00:00 2001
From: Alex Xu <alex_y_xu@yahoo.ca>
Date: Sat, 18 Feb 2017 11:31:04 -0500
Subject: [PATCH 4/5] x11-misc/x11vnc: bump to _p20161013-r1, bug 611662

---
 x11-misc/x11vnc/x11vnc-0.9.14_p20161013-r1.ebuild | 65 +++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 x11-misc/x11vnc/x11vnc-0.9.14_p20161013-r1.ebuild

diff --git a/x11-misc/x11vnc/x11vnc-0.9.14_p20161013-r1.ebuild b/x11-misc/x11vnc/x11vnc-0.9.14_p20161013-r1.ebuild
new file mode 100644
index 00000000000..e6c5bd1bd53
--- /dev/null
+++ b/x11-misc/x11vnc/x11vnc-0.9.14_p20161013-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools vcs-snapshot
+
+DESCRIPTION="A VNC server for real X displays"
+HOMEPAGE="https://libvnc.github.io/"
+SRC_URI="https://github.com/LibVNC/x11vnc/archive/e191071c1f375d04ba8f955ea0a30292a485999e.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
+# bug 609162
+IUSE="crypt fbcon libressl ssl threads xinerama zeroconf zlib"
+
+RDEPEND=">=net-libs/libvncserver-0.9.8[ssl?,threads=,zlib=]
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	>=x11-libs/libXtst-1.1.0
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:= )
+	)
+	xinerama? ( x11-libs/libXinerama )
+	zeroconf? ( >=net-dns/avahi-0.6.4 )
+"
+DEPEND="${RDEPEND}
+	x11-libs/libXt
+	x11-proto/inputproto
+	x11-proto/trapproto
+	x11-proto/recordproto
+	x11-proto/xproto
+	x11-proto/xextproto
+	xinerama? ( x11-proto/xineramaproto )"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	# --without-v4l because of missing video4linux 2.x support wrt #389079
+	# xtrap appears to be obsoleted by xtest here
+	econf \
+		$(use_with crypt) \
+		$(use_with fbcon fbdev) \
+		$(use_with ssl) \
+		$(use_with ssl crypto) \
+		$(use_with xinerama) \
+		$(use_with zeroconf avahi) \
+		--without-v4l \
+		--without-xtrap
+}
+
+src_install() {
+	default
+	newinitd "${FILESDIR}/${PN}.init.d" ${PN}
+	newconfd "${FILESDIR}/${PN}.conf.d" ${PN}
+}
-- 
2.11.0