Fixed libusb depends

gnupg-1.4.0.ebuild (text/plain), 3.01 KB, created by Diego Elio Pettenò (RETIRED) on 2004-12-17 19:23:29 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/gnupg-1.2.6.ebuild,v 1.16 2004/12/07 12:54:06 dragonheart Exp $

inherit eutils flag-o-matic

DESCRIPTION="The GNU Privacy Guard, a GPL pgp replacement"
HOMEPAGE="http://www.gnupg.org/"
SRC_URI="ftp://ftp.gnupg.org/gcrypt/gnupg/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc-macos ~s390 ~sparc ~x86 ~ia64 ~mips ~ppc64"
IUSE="X ldap nls static hkp finger mailto card readline caps zlib idea bzip2"

RDEPEND="!static? (
			ldap? ( net-nds/openldap )
			bzip2? ( app-arch/bzip2 )
			zlib? ( sys-libs/zlib )
		)
		X? ( || ( media-gfx/xloadimage media-gfx/xli ) )
		nls? ( sys-devel/gettext )
		card? ( dev-libs/libusb )
		dev-lang/perl
		virtual/libc
		virtual/mta
		readline? ( sys-libs/readline )"

DEPEND="ldap? ( net-nds/openldap )
		nls? ( sys-devel/gettext )
		zlib? ( sys-libs/zlib )
		bzip2? ( app-arch/bzip2 )
		card? ( dev-libs/libusb )
		dev-lang/perl
		virtual/libc"

src_unpack() {
	unpack ${A}

	use ppc64 && epatch ${FILESDIR}/gnupg-1.2.4.ppc64.patch
}

src_compile() {
	# Certain sparc32 machines seem to have trouble building correctly with 
	# -mcpu enabled.  While this is not a gnupg problem, it is a temporary
	# fix until the gcc problem can be tracked down.
	if [ "${ARCH}" == "sparc" ] && [ "${PROFILE_ARCH}" == "sparc" ]; then
		filter-flags -mcpu=supersparc -mcpu=v8 -mcpu=v7
	fi

	# `USE=static` support was requested in #29299
	use static && append-ldflags -static

	# Still needed?
	# Bug #6387, --enable-m-guard causes bus error on sparcs
	use sparc || myconf="${myconf} --enable-m-guard"

	if ! use zlib; then
		myconf="${myconf} --with-included-zlib"
	else
		myconf="${myconf} --without-included-zlib"
	fi

	use ppc-macos || append-ldflags -Wl,-z,now

	if use ppc-macos && use caps; then
		eerror "Capabilities support is only available for Linux."
	fi

	econf \
		`use_enable X photo-viewers` \
		`use_enable ldap` \
		`use_enable mailto` \
		`use_enable hkp` \
		`use_enable finger` \
		`use_enable nls` \
		`use_enable bzip2` \
		`use_enable card card-support` \
		`use_enable selinux selinux-support` \
		`use_enable x86 asm` \
		`use_with caps capabilities` \
		`use_with readline` \
		--enable-static-rnd=linux \
		--libexecdir=/usr/lib \
		--enable-sha512 \
		${myconf} || die
	emake || die
}

src_install() {
	emake DESTDIR=${D} libexecdir="/usr/lib/gnupg" install || die

	# keep the documentation in /usr/share/doc/...
	rm -rf "${D}/usr/share/gnupg/FAQ" "${D}/usr/share/gnupg/faq.html"

	dodoc AUTHORS BUGS ChangeLog INSTALL NEWS PROJECTS README THANKS \
		TODO VERSION doc/{FAQ,HACKING,DETAILS,ChangeLog,OpenPGP,faq.raw}

	docinto sgml
	dodoc doc/*.sgml

	dohtml doc/faq.html

	chmod u+s "${D}/usr/bin/gpg"
}

pkg_postinst() {
	einfo "gpg is installed suid root to make use of protected memory space"
	einfo "This is needed in order to have a secure place to store your"
	einfo "passphrases, etc. at runtime but may make some sysadmins nervous."
}