From cf10ded3f05f45db8437786823c7c769bed028d0 Mon Sep 17 00:00:00 2001
From: Alex Xu <alex_y_xu@yahoo.ca>
Date: Sun, 15 Jan 2017 11:19:24 -0500
Subject: [PATCH 4/4] net-libs/libvncserver: 0.9.11 bump, rm old patches

---
 net-libs/libvncserver/Manifest                   |  1 +
 net-libs/libvncserver/libvncserver-0.9.11.ebuild | 72 ++++++++++++++++++++++++
 2 files changed, 73 insertions(+)
 create mode 100644 net-libs/libvncserver/libvncserver-0.9.11.ebuild

diff --git a/net-libs/libvncserver/Manifest b/net-libs/libvncserver/Manifest
index eb03d4e9932..a0a440b0549 100644
--- a/net-libs/libvncserver/Manifest
+++ b/net-libs/libvncserver/Manifest
@@ -1,2 +1,3 @@
 DIST LibVNCServer-0.9.10.tar.gz 1415191 SHA256 ed10819a5bfbf269969f97f075939cc38273cc1b6d28bccfb0999fba489411f7 SHA512 eb637dfb72dc50fb713a715c9d0cc8824a6871527c2edb497e70c92e2e708021fbd5d8134f2dee6a9e90d1c8fd3fee53c5f5ece790c2804e938011a980ffceae WHIRLPOOL 821234e772d15668b88bd99e72345a7b5d1a9072fd868ddd47fb47a1e4c6b3c1c2de2380622231a968bd98ac05f20a004a80dfbe43db77f8170056121207b9f4
+DIST LibVNCServer-0.9.11.tar.gz 1413739 SHA256 193d630372722a532136fd25c5326b2ca1a636cbb8bf9bb115ef869c804d2894 SHA512 e473c081b68dd3cdd96a1756b4f4945ece79d3c8e4cef62140be1699671555fc16d3080e81d764197a14ea83203ffcd0e18c3cc182e012d036e3faae943003fb WHIRLPOOL 98a24e533a0b8065d1f3c52672b601750f26a89e29cee8e3b253cc15219d0249befd1aa2735f06351d7911777ff7dc3ce39dc903f7046f39a0abf0af277dff11
 DIST libvncserver-0.9.10_p20160127.tar.gz 1407878 SHA256 cac045bc068e567e9639624e66fb0db18205d93c12845366e16b8351b70ebd2e SHA512 3e8079d814c624e7c8f6f4dd91dfdf05e035ec489fc87a797a4a08b4f8998156b420b941b94c48f6b5f783f1a962f802e83d4bbdefc1f4093837331c8247676d WHIRLPOOL 4884303a7071c450f06b93b2b483903d45f871c0d6e1dd55f2a1c141feb3eca97d9fbcd32e8f02bf6413beb6a11e70f53b498f15172bb2f04be1796045095331
diff --git a/net-libs/libvncserver/libvncserver-0.9.11.ebuild b/net-libs/libvncserver/libvncserver-0.9.11.ebuild
new file mode 100644
index 00000000000..80bc91d2d90
--- /dev/null
+++ b/net-libs/libvncserver/libvncserver-0.9.11.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools eutils multilib-minimal
+
+CAP_PN=LibVNCServer
+
+DESCRIPTION="library for creating vnc servers"
+HOMEPAGE="http://libvncserver.sourceforge.net/"
+SRC_URI="https://github.com/LibVNC/${PN}/archive/${CAP_PN}-${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux"
+IUSE="+24bpp gcrypt gnutls ipv6 +jpeg libressl +png ssl static-libs systemd test threads +zlib"
+REQUIRED_USE="!gnutls? ( ssl? ( threads ) )"
+
+DEPEND="
+	gcrypt? ( >=dev-libs/libgcrypt-1.5.3:0[${MULTILIB_USEDEP}] )
+	gnutls? (
+		>=net-libs/gnutls-2.12.23-r6[${MULTILIB_USEDEP}]
+		>=dev-libs/libgcrypt-1.5.3:0[${MULTILIB_USEDEP}]
+	)
+	!gnutls? (
+		ssl? (
+			!libressl? ( >=dev-libs/openssl-1.0.1h-r2:0[${MULTILIB_USEDEP}] )
+			libressl? ( dev-libs/libressl[${MULTILIB_USEDEP}] )
+		)
+	)
+	jpeg? ( >=virtual/jpeg-0-r2:0[${MULTILIB_USEDEP}] )
+	png? ( >=media-libs/libpng-1.6.10:0[${MULTILIB_USEDEP}] )
+	systemd? ( sys-apps/systemd:= )
+	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${PN}-${CAP_PN}-${PV}"
+
+DOCS=( AUTHORS ChangeLog NEWS README TODO )
+
+src_prepare() {
+	default
+
+	sed -i -r \
+		-e "/^SUBDIRS/s:\<$(usex test '' 'test|')client_examples|examples\>::g" \
+		Makefile.am || die
+
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	econf \
+		--disable-silent-rules \
+		$(use_enable static-libs static) \
+		$(use_with 24bpp) \
+		$(use_with gnutls) \
+		$(usex gnutls --with-gcrypt $(use_with gcrypt)) \
+		$(usex gnutls --without-ssl $(use_with ssl)) \
+		$(use_with ipv6) \
+		$(use_with jpeg) \
+		$(use_with png) \
+		$(use_with threads pthread) \
+		$(use_with zlib)
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files
+}
-- 
2.11.0