amanda-afs-0.0.3-r3.ebuild

amanda-afs-0.0.3-r3.ebuild (text/plain), 1.31 KB, created by Steve-o on 2004-12-14 13:46:30 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/amanda/amanda-2.4.4_p2.ebuild,v 1.5 2004/06/24 21:22:32 agriffis Exp $

inherit eutils

DESCRIPTION="AFS Tools for AMANDA"
HOMEPAGE="http://www.amanda.org/docs/howto-afs.html"
SRC_URI="ftp://ftp.ccmr.cornell.edu/pub/amanda-afs/amanda-afs-${PV}.tar.gz"
LICENSE="as-is"
SLOT="0"
KEYWORDS="~x86"
RDEPEND="dev-lang/perl
		net-fs/openafs"
DEPEND="${RDEPEND}"
IUSE=""

src_unpack() {
	unpack ${A} || die "unpack failed"
	cd ${WORKDIR}/${PN}

	#fix typos and link error
	epatch ${FILESDIR}/amanda-afs-0.0.3.diff

	#change install to /usr/sbin from /usr/local
	sed -i \
		-e "s:/usr/local/amanda/sbin:${D}/usr/sbin:" \
		${WORKDIR}/${PN}/Makefile.conf \
		|| die "sed Makefile.conf failed"

	#change hardcoded links put in gtar-wrapper.pl by Makefile
	sed -i \
		-e "s:%\$(INSTALL_DIR)%:%/usr/sbin%:" \
		${WORKDIR}/${PN}/Makefile \
		|| die "sed Makefile failed"

	#change perl location
	sed -i \
		-e "s:/usr/local/bin/perl:/usr/bin/perl:" \
		${WORKDIR}/${PN}/gtar-wrapper.pl.in \
		|| die "sed gtar-wrapper.pl.in failed"
}

src_compile() {
	cd ${WORKDIR}/${PN}
	emake || die "emake failed"
}

src_install() {
	cd ${WORKDIR}/${PN}
	make install || die "make install failed"
	dodoc README INSTALL
}