kdocker-1.0.ebuild (few changes)

kdocker-1.0.ebuild (text/plain), 1.14 KB, created by Przemyslaw Maciag (RETIRED) on 2004-12-12 04:35:15 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils

DESCRIPTION="KDocker will help you dock any application in the system tray."
HOMEPAGE="http://kdocker.sourceforge.net/"
SRC_URI="mirror://sourceforge/kdocker/${P}.tar.gz"
LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~ppc ~x86"
IUSE=""

DEPEND="virtual/x11
	>=x11-libs/qt-3"

S="${WORKDIR}/${PN}"

src_unpack() {
	unpack ${A}

	cd ${S}
	sed -i \
		-e '/^INSTALL_PATH/s:=.*:= /usr/share/kdocker:' \
		-e '/^target\.path/s:=.*:= /usr/bin:' \
		kdocker.pro \
		|| die "sed kdocker.pro failed"
	epatch ${FILESDIR}/${PN}-desktop_file.patch
}

src_compile() {
	qmake kdocker.pro \
		QMAKE_CXXFLAGS_RELEASE="${CXXFLAGS}" \
		QMAKE_RPATH= \
		|| die "qmake failed"
	emake || die "emake failed"
}

src_install() {
	make INSTALL_ROOT=${D} install || die "install failed"
	dodoc AUTHORS BUGS ChangeLog CREDITS HACKING INSTALL README TODO VERSION

	# cleaning docs after make install
	rm -rf ${D}/usr/share/${PN}/docs

	# cleaning unneeded locales
	for i in cs es fr; do
		! echo ${LINGUAS} | grep $i && rm ${D}/usr/share/${PN}/i18n/${PN}_$i.qm
	done;
}