tipa-1.3.ebuild

tipa-1.3.ebuild (text/plain), 1.18 KB, created by Alex Linke on 2004-12-09 01:41:10 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

DESCRIPTION="IPA fonts for LaTeX"
HOMEPAGE="http://www.l.u-tokyo.ac.jp/~fkr/"
SRC_URI="http://www.l.u-tokyo.ac.jp/~fkr/tipa/${P}.tar.gz"

LICENSE="LPPL-1.2"
SLOT="0"
KEYWORDS="x86"

IUSE=""

DEPEND="virtual/tetex"
RDEPEND=""

S=${WORKDIR}/${P}

src_compile() {
	# install files under /usr/share/texmf/
	einfo "Fixing PREFIX in 'Makefile'."
	sed -e \
	's/PREFIX=\/usr\/local\/teTeX\/share\/texmf/PREFIX=\/usr\/share\/texmf/' \
		-i Makefile || die "sed failed"

	einfo "Fixing lack of DESTDIR support in 'Makefile'."
	sed -e 's/\($(TEXDIR)\)/$(DESTDIR)\/\1/' \
		-e 's/\($(FONTDIR)\)/$(DESTDIR)\/\1/g' \
		-e 's/\($(MAPDIR)\)/$(DESTDIR)\/\1/' \
		-i Makefile || die "sed failed"

	# removing `mktexlsr` from Makefile (leads to access violation)
	sed -e 's/-mktexlsr//' -i Makefile || die "sed failed"
}

src_install() {
	make DESTDIR=${D} install || die "make install failed."
	dodoc doc/*.{tex,sty,bib,bbl} || die "dodoc failed."

	einfo "A huge documentation can be found in '/usr/share/doc/${P}'."
}

pkg_postinst() {
	einfo "Running mktexlsr..."
	mktexlsr || die "mktexlsr failed"
}