# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6

inherit gnome2-utils

DESCRIPTION="Chromium B.S.U. - an arcade game"
HOMEPAGE="http://chromium-bsu.sourceforge.net/"
SRC_URI="mirror://sourceforge/chromium-bsu/${P}.tar.gz"

LICENSE="Clarified-Artistic"
SLOT="0"
KEYWORDS="~amd64 ~x86"

IUSE="mixer nls"

RDEPEND="media-fonts/dejavu
	media-libs/quesoglc
	media-libs/libsdl2[X]
	media-libs/sdl2-image[png]
	virtual/glu
	virtual/opengl
	x11-libs/libXmu
	mixer? ( media-libs/sdl2-mixer )
	!mixer? (
		media-libs/freealut
		media-libs/openal
	)
	nls? ( virtual/libintl )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

src_configure() {
	econf \
		--enable-glc \
		--disable-ftgl \
		--enable-sdl2 \
		--disable-glut \
		--enable-sdl2image \
		--disable-glpng \
		--disable-sdl \
		--disable-sdlimage \
		--disable-sdlmixer \
		--docdir=/usr/share/doc/${PF}/html \
		$(use_enable mixer sdl2mixer) \
		$(use_enable !mixer openal) \
		$(use_enable nls)
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}