Ebuild

denemo-2.0.12.ebuild (text/plain), 1.79 KB, created by Nikita Zlobin on 2016-10-27 20:17:00 UTC

# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5
inherit eutils fdo-mime base autotools-utils

DESCRIPTION="A music notation editor"
HOMEPAGE="http://www.denemo.org/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"

LICENSE="GPL-3 OFL-1.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="nls gtk2 alsa jack +portaudio portmidi fluidsynth rubberband evince aubio guile"

COMMON_DEPEND="
	evince? ( >=app-text/evince-3 )
	dev-libs/libxml2:2
	guile? ( >=dev-scheme/guile-1.8 )
	gnome-base/librsvg:2
	media-libs/fontconfig:1.0
	>=media-libs/libsmf-1.3
	media-libs/libsndfile
	gtk2? ( x11-libs/gtk+:2 )
	!gtk2? ( x11-libs/gtk+:3 )
	x11-libs/gtksourceview:3.0
	alsa? ( media-libs/alsa-lib )
	jack? ( >=media-sound/jack-audio-connection-kit-0.102 )
	fluidsynth? ( media-sound/fluidsynth )
	portaudio? (
		media-libs/portaudio
		aubio? ( media-libs/aubio )
		sci-libs/fftw:3.0
		media-libs/libsamplerate
	)
	portmidi? ( media-libs/portmidi )
	rubberband? ( media-libs/rubberband )"

RDEPEND="${COMMON_DEPEND}
	media-sound/lilypond"
DEPEND="${COMMON_DEPEND}
	sys-devel/flex
	virtual/pkgconfig
	virtual/yacc
	nls? ( sys-devel/gettext )"

DOCS=( AUTHORS ChangeLog docs/{DESIGN{,.lilypond},GOALS,TODO} NEWS )
PATCHES=( "${FILESDIR}/${PN}-2.0.6-desktop.patch" )

src_configure() {
	local myeconfargs=(
		$(use_enable nls)
		$(usex gtk2 --enable-gtk2 --enable-gtk3)
		$(use_enable alsa)
		$(use_enable jack)
		$(use_enable portaudio)
		$(use_enable portmidi)
		$(use_enable fluidsynth)
		$(use_enable rubberband)
		$(use_enable aubio)
		$(use_enable evince)
		$(if ! use guile; then echo --disable-guile_1_8 --disable-guile_2_0; fi)
		--enable-x11
	)
	autotools-utils_src_configure
}

pkg_postinst() { fdo-mime_desktop_database_update; }
pkg_postrm() { fdo-mime_desktop_database_update; }