recoll-1.22.3.ebuild

recoll-1.22.3.ebuild (text/plain), 2.39 KB, created by Marcin Mirosław on 2016-10-21 08:47:02 UTC

# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI="5"

PYTHON_COMPAT=( python2_7 )
inherit qt4-r2 linux-info python-single-r1

DESCRIPTION="A personal full text search package"
HOMEPAGE="http://www.lesbonscomptes.com/recoll/"
SRC_URI="http://www.lesbonscomptes.com/recoll/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"

INDEX_HELPERS="7zip audio chm djvu dvi exif ical ics info lyx msdoc ocr pdf postscript rar rtf tex wordperfect xml"
IUSE="camelcase doc fam gui +inotify qt4 session +spell webkit ${INDEX_HELPERS}"

REQUIRED_USE="session? ( || ( inotify fam ) )"

DEPEND="
	virtual/libiconv
	>=dev-libs/xapian-1.0.12
	sys-libs/zlib
	spell? ( app-text/aspell )
	!inotify? ( fam? ( virtual/fam ) )
	qt4? ( dev-qt/qtcore:4[qt3support] )
	webkit? ( dev-qt/qtwebkit:4 )
	session? (
		inotify? ( x11-libs/libSM x11-libs/libICE )
		!inotify? (
			fam? ( x11-libs/libSM x11-libs/libICE )
		)
	)
"

RDEPEND="${DEPEND}
	app-arch/unzip
	sys-apps/sed
	virtual/awk
	7zip? ( dev-python/pylzma )
	audio? ( media-libs/mutagen )
	chm? ( dev-python/pychm )
	djvu? ( >=app-text/djvu-3.5.15 )
	dvi? ( virtual/tex-base )
	exif? ( media-libs/exiftool )
	gui? ( dev-python/libwnck-python )
	ical? ( dev-python/icalendar )
	ics? ( dev-python/icalendar )
	info? ( sys-apps/texinfo )
	lyx? ( app-office/lyx )
	msdoc? ( app-text/antiword )
	ocr? ( app-text/tesseract )
	pdf? ( app-text/poppler )
	postscript? ( app-text/pstotext )
	rar? ( dev-python/rarfile )
	rtf? ( app-text/unrtf )
	tex? ( dev-tex/detex )
	wordperfect? ( app-text/libwpd:0.9 )
	xml? ( dev-libs/libxml2[python,${PYTHON_USEDEP}] dev-libs/libxslt[python,${PYTHON_USEDEP}] )
"

pkg_setup() {
	if use inotify; then
		CONFIG_CHECK="~INOTIFY_USER"
		check_extra_config
	fi
	python-single-r1_pkg_setup
}

src_prepare() {
	python_fix_shebang filters
	default
}

src_configure() {
	local qtconf
	if use qt4 || use webkit; then
		qtconf="QMAKEPATH=/usr/bin/qmake"
	fi

	econf \
		$(use_enable camelcase) \
		$(use_enable qt4 qtgui) \
		$(use_enable session x11mon) \
		$(use_with fam) \
		$(use_with inotify) \
		$(use_with spell aspell) \
		${qtconf} \
		--enable-recollq

	if use qt4; then
		cd qtgui && eqmake4 ${PN}.pro && cd ..
	fi
}

src_install() {
	emake DESTDIR="${D}" install
	# html docs should be placed in /usr/share/doc/${PN}/html
	use doc && dohtml "${ED}"/usr/share/recoll/doc/*
	rm -r "${ED}/usr/share/recoll/doc"
}