pgadmin4-1.0.ebuild

pgadmin4-1.0.ebuild (text/plain), 2.11 KB, created by Chris Mayo on 2016-10-10 18:48:58 UTC

# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6

# Restricted to Python 2.7 for flask-security
PYTHON_COMPAT=( python2_7 )

inherit python-single-r1 qmake-utils

DESCRIPTION="flask GUI for PostgreSQL"
HOMEPAGE="http://www.pgadmin.org/"
SRC_URI="mirror://postgresql/pgadmin3/${PN}/v${PV}/source/${P}.tar.gz"

LICENSE="POSTGRESQL"
KEYWORDS="~amd64 ~x86"
SLOT="0"
IUSE="doc qt4 qt5"

REQUIRED_USE="^^ ( qt4 qt5 )
	${PYTHON_REQUIRED_USE}"

COMMON_DEPEND="${PYTHON_DEPS}
	qt4? (
		dev-qt/qtgui:4
		dev-qt/qtwebkit:4
	)
	qt5? (
		dev-qt/qtwidgets
		dev-qt/qtwebkit:5
	)"

DEPEND="${COMMON_DEPEND}
	doc? ( dev-python/sphinx )"

RDEPEND="${COMMON_DEPEND}
	dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
	dev-python/python-dateutil[${PYTHON_USEDEP}]
	dev-python/django-htmlmin[${PYTHON_USEDEP}]
	dev-python/flask[${PYTHON_USEDEP}]
	>=dev-python/flask-babel-0.11.1[${PYTHON_USEDEP}]
	dev-python/flask-gravatar[${PYTHON_USEDEP}]
	dev-python/flask-security[${PYTHON_USEDEP}]
	dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
	dev-python/psycopg[${PYTHON_USEDEP}]
	dev-python/pycrypto[${PYTHON_USEDEP}]
	dev-python/sqlparse[${PYTHON_USEDEP}]"
# see requirements_py2.txt for more dependencies

PYTHON_REQ_USE="sqlite"

S="${WORKDIR}"/${P}/runtime

src_prepare() {
	cd "${WORKDIR}"/${P} || die
	default
}

src_configure() {
	if use qt4 ; then
		eqmake4
	else
		eqmake5
	fi
}

src_compile() {
	default
	if use doc; then
		cd "${WORKDIR}"/${P} || die
		emake docs || die
	fi
}

src_install() {
	dobin pgAdmin4

	cd "${WORKDIR}"/${P} || die
	insinto /usr/share/${PN}
	doins -r web
	echo "SERVER_MODE = False" > "${D}"/usr/share/${PN}/web/config_local.py || die
	python_optimize "${D}"/usr/share/${PN}/web

	local CONFIG_DIR="/etc/xdg/pgAdmin Development Team"
	local CONFIG_FILE="pgAdmin 4.conf"
	insinto "${CONFIG_DIR}"
	newins "${FILESDIR}"/pgAdmin4.conf "${CONFIG_FILE}"
	echo "PythonPath=$(python_get_sitedir)" >> "${D}${CONFIG_DIR}/${CONFIG_FILE}" || die

	if use doc; then
		rm -r docs/en_US/_build/html/_sources || die
		insinto /usr/share/${PN}/docs/en_US/_build
		doins -r docs/en_US/_build/html
	fi
}