ufo2000-svn-0.4.1.ebuild

ufo2000-svn-0.4.1.ebuild (text/plain), 2.39 KB, created by Siarhei Siamashka on 2004-11-28 07:32:38 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/ufo2000/ufo2000-0.4.0.353.ebuild,v 1.5 2004/07/01 05:34:11 mr_bones_ Exp $

inherit subversion games

ESVN_REPO_URI="http://lxnt.info:8888/repos/ufo2k/trunk"
ESVN_BOOTSTRAP=""

DESCRIPTION="Free multiplayer remake of X-COM (UFO: Enemy Unknown)"
HOMEPAGE="http://ufo2000.sourceforge.net/"
SRC_URI="ftp://ftp.microprose.com/pub/mps-online/x-com/xcomdemo.zip
	ftp://ftp.microprose.com/pub/mps-online/demos/terror.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-* ~x86"
IUSE="oggvorbis"

DEPEND="virtual/libc
	>=media-libs/allegro-4.0.3
	>=dev-lang/lua-5.0.2
	>=dev-games/hawknl-1.66
	dev-libs/expat
	oggvorbis? ( >=media-libs/aldumb-0.9.2
		media-libs/libogg
		media-libs/libvorbis )
	!games-strategy/ufo2000"

src_compile() {

	cd "${S}/XCOMDEMO"
	unpack xcomdemo.zip
	unzip -qLL XCOM.EXE -d ..
	rm XCOM.EXE
	mv ../xcomdemo/* "${S}/XCOMDEMO/"

	cd "${S}/TFTDDEMO"
	unpack terror.zip
	unzip -qLL TFTD.ZIP
	rm TFTD.ZIP
	
	cd "${S}"

	if use oggvorbis
	then
		emake \
			DATA_DIR="${GAMES_DATADIR}/${PN}" \
			OPTFLAGS="${CXXFLAGS}" \
			dumbogg=1 \
				|| die "emake failed"
	else
		emake \
			DATA_DIR="${GAMES_DATADIR}/${PN}" \
			OPTFLAGS="${CXXFLAGS}" \
				|| die "emake failed"
	fi
}

src_install() {
	dogamesbin ufo2000 || die "dogamesbin failed"
	dodir "${GAMES_DATADIR}/${PN}"
	sed -i 's,host = lxnt.info,host = lxnt.info:2001,g' ufo2000.default.ini
	cp -R arts newmaps newmusic newunits init-scripts script \
		XCOMDEMO XCOM TFTDDEMO TFTD translations \
		*.dat ufo2000.default.ini soundmap.xml \
			"${D}/${GAMES_DATADIR}/${PN}" \
				|| die "cp failed"
	keepdir "${GAMES_DATADIR}/${PN}/newmusic"
	echo "Please copy data files from X-COM here" > \
		"${D}/${GAMES_DATADIR}/${PN}/XCOM/readme.txt"
	echo "Please copy data files from TFTD here" > \
		"${D}/${GAMES_DATADIR}/${PN}/TFTD/readme.txt"
	dodoc *.txt INSTALL AUTHORS HACKING ChangeLog || die "dodoc failed"
	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst
	einfo "If you have a full version of X-COM, you can copy all the files"
	einfo "from the directory where you have it installed into:"
	einfo "   ${GAMES_DATADIR}/${PN}/XCOM"
	echo
	einfo "Likewise for Terror From The Deep, but to the directory:"
	einfo "   ${GAMES_DATADIR}/${PN}/TFTD"
	echo
	einfo "This will allow you to use more terrain types and units."
	echo
}