ebuild for sys-firmware/edk2-ovmf

edk2-ovmf-20160901.ebuild (text/plain), 2.06 KB, created by Mekong on 2016-09-14 12:16:27 UTC

# Copyright 2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5
PYTHON_COMPAT=( python2_7 )
inherit eutils multiprocessing toolchain-funcs python-single-r1 git-2

DESCRIPTION="EDK II Open Source UEFI Firmware"
HOMEPAGE="https://github.com/tianocore/edk2/tree/master/OvmfPkg"

LICENSE="BSD-2"
SLOT="0"
IUSE="debug +secure-boot +smm"

EGIT_REPO_URI="git://github.com/tianocore/edk2"
SRC_URI=""

# 20160805 "afd6b28915cac422294a28033ef83727b27ce216"
case ${PV} in
	99999999)
		KEYWORDS="-*"
		;;
	20160901)
		EGIT_COMMIT="8953d69a5ca7f18f80f46e67da95c2527ca6ee89"
		KEYWORDS="-* ~amd64"
		;;
# 	*)
#		EGIT_COMMIT="${PV}"
#		KEYWORDS="-* amd64"
#		;;
esac

MY_P="edk2-${PV}"
S="${WORKDIR}/${MY_P}"
EGIT_SOURCEDIRS="${S}"

OPENSSL_PV="1.0.2h"
OPENSSL_P="openssl-${OPENSSL_PV}"
SRC_URI+=" mirror://openssl/source/${OPENSSL_P}.tar.gz"

DEPEND=">=dev-lang/nasm-2.0.7
	sys-power/iasl"

RDEPEND=">=app-emulation/qemu-2.5
	"

pkg_setup() {
	python-single-r1_pkg_setup
}

src_unpack() {
	unpack ${A}
	git-2_src_unpack
}

src_prepare() {
	if use secure-boot; then
		local openssllib="${S}/CryptoPkg/Library/OpensslLib"
		mv "${WORKDIR}/${OPENSSL_P}" "${openssllib}" || die
		cd "${openssllib}/${OPENSSL_P}"
		epatch "${openssllib}/EDKII_${OPENSSL_P}.patch"
		cd "${openssllib}"
		sh -e ./Install.sh || die
	fi
}

src_configure() {
	./edksetup.sh || die

	TARGET_NAME=$(usex debug DEBUG RELEASE)
	TARGET_TOOLS="GCC$(gcc-version | tr -d .)"
	case $ARCH in
		amd64)	TARGET_ARCH=X64 ;;
		x86)	TARGET_ARCH=IA32 ;;
		*)		die "Unsupported $ARCH" ;;
	esac
}

src_compile() {
	emake ARCH=${TARGET_ARCH} -C BaseTools -j1

	echo "${TARGET_TOOLS}"

	./OvmfPkg/build.sh \
		-a "${TARGET_ARCH}" \
		-b "${TARGET_NAME}" \
		-t "${TARGET_TOOLS}" \
		-n $(makeopts_jobs) \
		-D SECURE_BOOT_ENABLE=$(usex secure-boot TRUE FALSE) \
		-D SMM_REQUIRE=$(usex smm TRUE FALSE) \
		-D FD_SIZE_2MB \
		|| die "OvmfPkg/build.sh failed"
}

src_install() {
	local fv="Build/Ovmf${TARGET_ARCH}/${TARGET_NAME}_${TARGET_TOOLS}/FV"
	insinto /usr/share/${PN}
	doins "${fv}"/OVMF{,_CODE,_VARS}.fd
}