# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6

# This *has* to be set before inheriting l10n to get linguas_* added to IUSE
PLOCALES="bg_BG ca cs da_DK de_CH de_DE en_GB es_ES et_EE fi_FI fr_FR he it_IT
	lv_LV nb_NO nl_NL pl_PL pt_BR pt_PT ro_RO ru_RU sk_SK sv_SE tr zh_TW"

inherit cmake-utils l10n

MY_P=${P/s/S}
S="${WORKDIR}/${MY_P}"

DESCRIPTION="An open source dive log program"
HOMEPAGE="https://subsurface-divelog.org/"
SRC_URI="https://subsurface-divelog.org/downloads/${MY_P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="bluetooth +doc -marble -print -serial usb"

RDEPEND="
	dev-db/sqlite:3
	>=dev-libs/libdivecomputer-0.4.2[usb?]
	>=dev-libs/libgit2-0.23.1
	dev-libs/libxml2:2
	dev-libs/libxslt
	dev-libs/libzip
	dev-qt/linguist-tools:5
	dev-qt/qtconcurrent:5
	dev-qt/qtcore:5
	dev-qt/qtnetwork:5
	dev-qt/qtsvg:5
	dev-qt/qttest:5
	dev-qt/qtwebkit:5
	dev-qt/qtwidgets:5
	net-libs/libssh2
	net-misc/curl
	bluetooth? ( dev-qt/qtbluetooth:5 )
	marble? ( kde-apps/marble:5 )
	print? (
		dev-libs/grantlee:5
		dev-qt/qtprintsupport:5
	)
	serial? ( dev-embedded/libftdi:1 )
	usb? ( virtual/libusb:1 )
"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	doc? ( app-text/asciidoc )
"

src_configure() {
	local mycmakeargs=(
		-DUSE_LIBGIT23_API=1
		-DBTSUPPORT=$(usex bluetooth)
		-DFTDISUPPORT=$(usex serial)
		-DNO_DOCS=$(usex !doc)
		-DNO_MARBLE=$(usex !marble)
		-DNO_PRINTING=$(usex !print)
	)
	cmake-utils_src_configure
}

rm_trans() {
	rm "${D}usr/share/${PN}/translations/${PN}_${1}.qm" || die "rm ${PN}_${1}.qm failed"
}

src_install() {
	cmake-utils_src_install

	l10n_for_each_disabled_locale_do rm_trans
	# this is not a translation but present (no need to die if not present)
	rm "${D}usr/share/${PN}/translations/${PN}_source.qm"
}