[patch] foo2zjs-20041117.ebuild

foo2zjs-20041117.ebuild (text/plain), 1.66 KB, created by Stefan Schweizer (RETIRED) on 2004-11-17 04:58:29 UTC

# Copyright 1999-2004 Gentoo Technologies, Inc.
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils flag-o-matic

DESCRIPTION="Support for printing to ZjStream-based printers"
HOMEPAGE="http://foo2zjs.rkkda.com/"
SRC_URI="http://foo2zjs.rkkda.com/${PN}.tar.gz
	getweb? (
		ftp://ftp.minolta-qms.com/pub/crc/out_going/win/m23dlicc.exe
		ftp://ftp.minolta-qms.com/pub/crc/out_going/win2000/m22dlicc.exe
		ftp://ftp.minolta-qms.com/pub/crc/out_going/windows/cpplxp.exe
		ftp://192.151.53.86/pub/softlib/software2/COL2222/lj-10067-2/lj1005hostbased-en.exe
		ftp://ftp.hp.com/pub/softlib/software1/lj1488/lj-1145-2/lj1488en.exe
	)"
RESTRICT="nomirror"
LICENSE="GPL-2"
SLOT="0"
IUSE="cups foomaticdb getweb usb"
DEPEND="cups? ( net-print/cups )
	foomaticdb? ( net-print/foomatic )
	usb? ( sys-apps/hotplug )"
KEYWORDS="-* ~x86 ~amd64"
S=${WORKDIR}/${PN}

src_unpack() {
	unpack ${PN}.tar.gz

	epatch ${FILESDIR}/${P}-Makefile.patch
	epatch ${FILESDIR}/hp-printer-udev.patch

	# link getweb files in ${S} to get unpacked
	# sed takes out the first entry
	if use getweb ; then
		for i in ${A/foo2zjs.tar.gz /}
		do
			ln -s ${DISTDIR}/${i} ${S}
		done
	fi

	cd ${S}
}

src_compile() {
	# unpack the firmware
	if use getweb ; then
		emake getweb || die "Failed building getweb script"
		# remove wget as we got the firmware with portage
		sed -si "s/.*wget.*//" getweb
		./getweb all
	fi
	emake || die
}

src_install() {
	use foomaticdb && dodir /usr/share/foomatic/db/source

	use cups && dodir /usr/share/cups/model

	make DESTDIR=${D} install \
		|| die "make install failed"

	use usb && make DESTDIR=${D} install-hotplug \
		|| die "make install-hotplug failed"
}