buddha-1.2-r1.ebuild

buddha-1.2-r1.ebuild (text/plain), 1.08 KB, created by Duncan Coutts (RETIRED) on 2004-11-16 17:38:07 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit base ghc-package

DESCRIPTION="A declarative debugger for Haskell 98"
HOMEPAGE="http://www.cs.mu.oz.au/~bjpop/buddha/"
SRC_URI="http://www.cs.mu.oz.au/~bjpop/buddha/download/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"

KEYWORDS="~x86"

IUSE=""

RDEPEND=">=virtual/ghc-6.0"

DEPEND="${RDEPEND}"

src_compile() {
	# lets put the interface files in a sensible place shall we?
	sed -i 's:AM_IFACEDIR = $(pkgdatadir)/ifaces:AM_IFACEDIR = $(pkglibdir)/ifaces:' \
		${S}/data/Makefile.in ${S}/libbuddha/Makefile.in ${S}/prelude/Buddha/Makefile.in

	econf --libdir=$(ghc-libdir) || die "Configure failed"

	# Makefile has no parallelism
	emake -j1 || die "Make failed"
}

src_install() {

	make DESTDIR=${D} install || die "Make install failed"

	# fix up the location of the .i files that we didn't want to relocate
	mkdir ${D}/usr/share/buddha/ifaces
	mv ${D}/$(ghc-libdir)/buddha/ifaces/*.i ${D}/usr/share/buddha/ifaces/

	#note that buddha's ghc packages do not need to be registered
}