websvn-2.3.3-r1.ebuild

websvn-2.3.3-r1.ebuild (text/plain), 1.06 KB, created by Michael Orlitzky on 2016-07-11 22:40:56 UTC

# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6

inherit eutils webapp

MY_P="${P//_/}"

DESCRIPTION="Web-based browser for Subversion (SVN) repositories in PHP"
HOMEPAGE="http://www.websvn.info/ http://websvn.tigris.org/"
DOWNLOAD_NUMBER="49056"
SRC_URI="http://websvn.tigris.org/files/documents/1380/${DOWNLOAD_NUMBER}/${MY_P}.tar.gz"

LICENSE="GPL-2"
IUSE="enscript"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"

DEPEND=""
RDEPEND="dev-lang/php[xml]
	dev-vcs/subversion
	virtual/httpd-php
	enscript? ( app-text/enscript )"
RESTRICT="mirror"

S="${WORKDIR}/${MY_P}"

src_install() {
	webapp_src_preinst

	DOCS=( changes.txt )
	HTML_DOCS=( doc/* )
	einstalldocs

	mv include/{dist,}config.php || die "failed to rename dist config"
	rm -rf license.txt changes.txt doc/ || die "failed to remove docs"

	insinto "${MY_HTDOCSDIR}"
	doins -r .

	webapp_configfile "${MY_HTDOCSDIR}"/include/config.php
	webapp_configfile "${MY_HTDOCSDIR}"/wsvn.php

	webapp_serverowned "${MY_HTDOCSDIR}"/cache

	webapp_src_install
}