tecnoballz-0.90.ebuild

tecnoballz-0.90.ebuild (text/plain), 1.52 KB, created by Mr. Bones. (RETIRED) on 2004-11-08 03:49:00 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-action/powermanga/powermanga-0.79.ebuild,v 1.2 2004/08/08 03:18:15 mr_bones_ Exp $

inherit games

DESCRIPTION="A Brick Breaker with 50 levels of game and 11 special levels"
HOMEPAGE="http://linux.tlk.fr/"
SRC_URI="http://linux.tlk.fr/games/TecnoballZ/download/${P}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="x86"
IUSE=""

DEPEND="virtual/libc
	>=media-libs/libsdl-1.2
	media-libs/libmikmod
	media-libs/sdl-mixer"

S="${WORKDIR}/${PN}"

src_unpack() {
	unpack ${A}
	cd "${S}"
	sed -i \
		-e '/^CC/d; /^CXX/d; /^PREFIX/d' \
		-e "s:^EXEDIR.*=:& ${GAMES_BINDIR}:" \
		-e "s:^MANDIR.*=:& /usr/share/man:" \
		-e "s:^DATADIR.*=:& ${GAMES_DATADIR}/${PN}:" \
		-e "s:^SCOrEDIR.*=:& ${GAMES_STATDIR}:" \
		src/Makefile \
		|| die "sed failed"
	sed -i \
		-e "s:/var/lib/games/tecnoballz.hi:${GAMES_STATEDIR}/tecnoballz.hi:" \
		-e "s:/usr/share/games/tecnoballz:${GAMES_DATADIR}/tecnoballz:" \
		src/ressources.cc \
		|| die "sed failed"
	find src/TecnoballZ/ -type d -name .xvpics -exec rm -rf \{\} \;
}

src_compile() {
	emake -C src || die "emake failed"
}

src_install() {
	dogamesbin src/tecnoballz || die "dogamesbin failed"
	newman man/tecnoballz.1 tecnoballz.6
	dodoc AUTHORS CHANGES README

	dodir "${GAMES_DATADIR}/tecnoballz"
	cp -r src/TecnoballZ "${D}${GAMES_DATADIR}/tecnoballz" \
		|| die "cp failed"

	insinto "${GAMES_STATEDIR}"
	insopts -m 660
	doins tecnoballz.hi || die "doins failed"
	prepgamesdirs
}