pjsip-2.4.5.ebuild

pjsip-2.4.5.ebuild (text/plain), 2.37 KB, created by Alex Xu (Hello71) on 2016-05-12 14:15:50 UTC

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6

inherit flag-o-matic

DESCRIPTION="free and open source multimedia communication library"
HOMEPAGE="http://www.pjsip.org/"
SRC_URI="http://www.pjsip.org/release/${PV}/pjproject-${PV}.tar.bz2"
KEYWORDS="~amd64 ~x86"

LICENSE="GPL-2"
SLOT="0"
IUSE="alsa amr debug doc epoll examples ffmpeg g711 g722 g7221 gsm ilbc ipv6 l16 openh264 oss resample sdl speex ssl static-libs v4l2"

RDEPEND="alsa? ( media-libs/alsa-lib media-libs/portaudio[alsa] )
	amr? ( media-libs/opencore-amr )
	ffmpeg? ( virtual/ffmpeg:= )
	gsm? ( media-sound/gsm )
	ilbc? ( dev-libs/ilbc-rfc3951 )
	openh264? ( media-libs/openh264 )
	oss? ( media-libs/portaudio[oss] )
	resample? ( media-libs/libsamplerate )
	sdl? ( media-libs/libsdl )
	speex? ( media-libs/speex )
	net-libs/libsrtp
	ssl? ( dev-libs/openssl:= )"
DEPEND="${DEPEND}
	virtual/pkgconfig"

REQUIRED_USE="alsa? ( !oss ) oss? ( !alsa )"

S="${WORKDIR}/pjproject-${PV}"

PATCHES=( "${FILESDIR}/pjsip-resample_libsamplerate-include.patch" )

src_configure() {
	myconf=()

	use ipv6 && append-flags -DPJ_HAS_IPV6=1

	use debug || append-flags -DNDEBUG=1

	if use alsa || use oss; then
		myconf+=( --with-external-pa )
	else
		myconf+=( --enable-ext-sound )
	fi

	econf \
		--enable-shared \
		--disable-silk \
		--with-external-srtp \
		$(use_enable alsa sound) \
		$(use amr || echo --disable-opencore-amr) \
		$(use_enable epoll) \
		$(use ffmpeg || echo --disable-ffmpeg) \
		$(use_enable g711 g711-codec) \
		$(use_enable g722 g722-codec) \
		$(use_enable g7221 g7221-codec) \
		$(use_enable gsm gsm-codec) \
		$(use_with gsm external-gsm) \
		$(use_enable ilbc ilbc-codec) \
		$(use_enable l16 l16-codec) \
		$(use openh264 || echo --disable-openh264) \
		$(use_enable oss) \
		$(use_enable resample libsamplerate) \
		$(use_enable resample) \
		$(use sdl || echo --disable-sdl) \
		$(use_enable speex speex-aec) \
		$(use_enable speex speex-codec) \
		$(use_with speex external-speex) \
		$(use ssl || echo --disable-ssl) \
		$(use v4l2 || echo --disable-v4l2) \
		"${myconf[@]}"
}

src_compile() {
	emake dep
	emake
}

src_install() {
	DESTDIR="${D}" emake install

	if use doc; then
		dodoc README.txt README-RTEMS
	fi

	if use examples; then
		insinto "/usr/share/doc/${PF}"
		doins -r pjsip-apps/src/samples
	fi

	use static-libs || rm "${D}/usr/$(get_libdir)/*.a"
}