monetdb-4.4.0.ebuild

monetdb-4.4.0.ebuild (text/plain), 4.03 KB, created by Fabian Groffen on 2004-11-01 12:36:45 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /ufs/monet/repository/monetdb_portage/dev-db/monetdb/monetdb-4.4.0.ebuild,v 1.2 2004/10/26 08:17:54 fabian Exp $

inherit flag-o-matic eutils

SLOT="0"
LICENSE="MPL-1.0"
KEYWORDS="~x86 ~ppc ~ppc64 ~sparc ~amd64 ~ia64"
DESCRIPTION="A main-memory database for query processing at light-speed"
HOMEPAGE="http://monetdb.cwi.nl/"

PV_SQL=2.4.0
SRC_URI="mirror://sourceforge/monetdb/MonetDB-${PV}.tar.gz
		mirror://sourceforge/monetdb/MonetDB-SQL-${PV_SQL}.tar.gz"
IUSE="java"
DEPEND="sys-devel/flex
		sys-devel/bison
		=sys-devel/gcc-3.3*
		java? ( >=virtual/jdk-1.4* dev-java/java-config )"
RDEPEND="sys-apps/at"

check_java_config() {
	JDKHOME="`java-config --jdk-home`"
	if [[ -z "${JDKHOME}" || ! -d "${JDKHOME}" ]]; then
		NOJDKERROR="You need to use java-config to set your JVM to a JDK!"
		eerror "${NOJDKERROR}"
		die "${NOJDKERROR}"
	fi
}

src_unpack() {
	unpack ${A} || die

	epatch ${FILESDIR}/${P}-gentoo-conf.patch
	epatch ${FILESDIR}/${P}-gentoo-MapiClient.patch
}

src_compile() {
	# -O3 messes things up due to aggressive inlining
	replace-flags -O3 -O2

	if use java; then
		check_java_config
	fi

	# The tar has capitals, the ebuild doesn't...
	cd ${WORKDIR}/MonetDB-${PV}

	econf "--enable-optimize" || die
	emake || die "emake monetdb failed"

	# make the header files available to the sql compilation
	mkdir include
	cd include
	ln -s ../src/common
	ln -s ../src/gdk
	ln -s ../src/monet
	ln -s ../src/modules/plain
	ln -s ../src/modules/contrib
	ln -s ../src/mapi
	ln -s ../src/mapi/clients/C
	ln -s ../monetdb_config.h
	ln -s ../sysdefs.h

	cd ${WORKDIR}/MonetDB-${PV}
	mkdir -p lib/MonetDB
	cd lib/MonetDB
	find ../.. -name "lib_*" -exec ln -s {} ';' >& /dev/null
	ln -s . .libs

	cd ${WORKDIR}/MonetDB-${PV}/lib
	find .. -name "lib*" -exec ln -s {} ';' >& /dev/null
	ln -s . .libs

	cd ${WORKDIR}/MonetDB-${PV}
	mkdir bin
	cd bin
	ln -s ../src/mel/mel
	ln -s ../src/utils/Mx/Mx

	# enable the fool-script
	MYWD=`echo ${WORKDIR} | sed -re 's/\//\\\\\//g'`
	sed -r \
		-e "s/\\$\_MONETDB\_INCLUDEDIR/${MYWD}\/MonetDB-${PV}\/include/g" \
		-e "s/\\$\_MONETDB\_VERSION/${PV}/g" \
		-e "s/\\$\_MONETDB\_LIBS/-L${MYWD}\/MonetDB-${PV}\/lib\/MonetDB -L${MYWD}\/MonetDB-${PV}\/lib/g" \
		-e "s/\\$\_MONETDB\_MOD_PATH/${MYWD}\/MonetDB-${PV}\/include/g" \
		-e "s/\\$\_MONETDB\_PREFIX/${MYWD}\/MonetDB-${PV}/g" \
		-e "s/\\$\_MONETDB\_CLASSPATH/${MYWD}\/MonetDB-${PV}\/src\/mapi\/clients\/java\/mapi.jar/g" \
		${FILESDIR}/monetdb_config.sh > \
			${WORKDIR}/MonetDB-${PV}/bin/monetdb-config
	chmod 744 ${WORKDIR}/MonetDB-${PV}/bin/monetdb-config

	cd ${WORKDIR}/sql-${PV_SQL}
	econf MONETDB_CONFIG=${WORKDIR}/MonetDB-${PV}/bin/monetdb-config \
		"--with-monet=${WORKDIR}/MonetDB-${PV} --enable-optimize" || die
	emake || die "emake sql failed"
}

src_install() {
	# The tar has capitals, the ebuild doesn't...
	cd ${WORKDIR}/MonetDB-${PV}
	einstall || die "failed to install monetdb"

	cd ${WORKDIR}/sql-${PV_SQL}
	einstall || die "failed to install sql"

	exeinto /etc/init.d/
	newexe ${FILESDIR}/${PN}.init-${PV} monetdb || die "init.d script"

	insinto /etc/conf.d/
	newins ${FILESDIR}/${PN}.conf-${PV} monetdb || die "conf.d file"

	diropts -m750
	dodir /var/lib/MonetDB /var/log/${PN}

	cp ${FILESDIR}/${PN}-start.sh ${D}/var/lib/MonetDB/ || die "start script"
	chmod 744 ${D}/var/lib/MonetDB/${PN}-start.sh

	cp ${FILESDIR}/${PN}-stop.sh ${D}/var/lib/MonetDB/ || die "stop script"
	chmod 744 ${D}/var/lib/MonetDB/${PN}-stop.sh

	einfo "MonetDB/SQL has been installed on your system."
	einfo "You can start a session with the database using the MapiClient"
	einfo "program, or the JDBC Java client if you have Java installed."
	einfo ""
	einfo "use:"
	einfo "% MapiClient"
	einfo "or"
	einfo "java -jar /usr/lib/MonetDB/java/MonetDB_JDBC.jar -umonetdb"
	einfo "with initial password monetdb."
}

pkg_preinst() {
	enewgroup monetdb
	enewuser monetdb -1 /bin/bash /var/lib/MonetDB monetdb
}

pkg_postinst() {
	chown -R monetdb:monetdb /var/lib/MonetDB
	chown -R monetdb:monetdb /var/log/${PN}
}