# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI="5"

inherit eutils linux-info

MY_P=Hybrid
DESCRIPTION="Advanced multisystem video editor"
HOMEPAGE="http://www.selur.de/"
SRC_URI="abi_x86_32? ( http://www.selur.de/sites/default/files/${PN}_downloads/${MY_P}_${PV}_32bit_binary_qt521.zip )
	abi_x86_64? ( http://www.selur.de/sites/default/files/${PN}_downloads/${MY_P}_${PV}_64bit_binary_qt521.zip )
		http://www.selur.de/sites/default/files/${PN}_downloads/avisynth/avisynthExtension_160402.7z"

#free for personal use, no right to redistribute see http://www.selur.de/licence
LICENSE="free-noncomm"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="abi_x86_32 abi_x86_64 aac aften +audio bluray dts dvd faac ffmpeg flac memcoder mono mkv ogg opus sox subtitles qt4 tsmuxer vpx x264 x265 xvid"
RESTRICT="fetch"

#aac options - fhgaacenc, qaac, fdk-aac, neroaac
RDEPEND="
	app-emulation/wine[mono?]
	>=dev-qt/qtmultimedia-5.2
	>=dev-qt/qtwidgets-5.2
	>=dev-qt/qtxml-5.2
	>=dev-qt/qtnetwork-5.2
	>=media-video/mediainfo-0.7
	media-video/framecounter

	aac? (
		media-sound/fdkaac
		media-sound/neroaac
	)
	aften? ( >=media-libs/aften-0.0.8 )
	audio? (
		media-sound/delaycut
		>=media-video/mp4fpsmod-0.24
	)
	dts? ( media-sound/dcaenc )
	dvd? ( media-video/lsdvd )
	faac? ( media-libs/faac )
	ffmpeg? ( media-video/ffmpeg[encode] )
	flac? ( media-libs/flac )
	memcoder? ( media-video/mplayer[bluray?,dvd?,encode,xvid?] )
	mkv? ( media-video/mkvtoolnix )
	ogg? ( media-sound/vorbis-tools )
	opus? ( media-sound/opus-tools )
	sox? ( media-sound/sox )
	subtitles? (
		qt4? ( media-video/bdsup2sub++ )
		media-video/telxcc
	)
	tsmuxer? ( >=media-video/tsmuxer-2.6 )
	vpx? ( media-libs/libvpx )
	x264? ( media-video/x264-encoder )
	x265? (
		media-libs/kvazaar
		media-libs/x265
		media-video/divx265
	)
"
DEPEND=""

S="${WORKDIR}/"

pkg_setup() {
	CONFIG_CHECK="~BINFMT_MISC"
	ERROR_KERNEL_BINFMT_MISC="BINFMT_MISC should be enabled in the kernel to start installed Windows executables directly"
}

src_unpack() {
	if use abi_x86_64; then
		unpack ${MY_P}_${PV}_64bit_binary_qt521.zip
	else
		unpack ${MY_P}_${PV}_32bit_binary_qt521.zip
	fi
	unpack avisynthExtension_160402.7z
}

src_install() {
	insinto /opt/${PN}
	doins -r *.dll avisynthPlugins dynamic
	doins ${FILESDIR}/misc.ini

	exeinto /opt/${PN}
	doexe Hybrid *.exe avisynthPlugins/*.exe dynamic/*.exe
	dosym ../${PN}/${MY_P} /opt/bin/${MY_P}

	domenu ${FILESDIR}/hybrid.desktop
	doicon ${FILESDIR}/Hybrid.png
}

pkg_postinst() {
	einfo " In order to get Avisynth plugins working you must copy"
	einfo "avisynth.dll and DevIL.dll into system dll directory of"
	einfo "your wine install location which defaults to"
	einfo "        \"~/.wine/drive_c/windows/syswow64\""
}