speed-dreams-2.2.0.ebuild

speed-dreams-2.2.0.ebuild (text/plain), 3.10 KB, created by Wojciech Myrda on 2016-04-03 12:28:54 UTC

# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5

inherit versionator cmake-utils games

REV="6381"

DESCRIPTION="A fork of the famous open racing car simulator TORCS"
HOMEPAGE="http://speed-dreams.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${PV}/${PN}-src-base-${PV}-r${REV}.tar.xz
	 mirror://sourceforge/${PN}/${PV}/${PN}-src-partial-build-patch-2.0.0-r4687.tar.xz
	 addons? ( mirror://sourceforge/${PN}/${PV}/${PN}-src-hq-cars-and-tracks-${PV}-r${REV}.tar.xz )
	 addons? ( mirror://sourceforge/${PN}/${PV}/${PN}-src-more-hq-cars-and-tracks-${PV}-r${REV}.tar.xz )
	 extra? ( mirror://sourceforge/${PN}/${PV}/${PN}-src-unmaintained-${PV}-r${REV}.tar.xz )
	 extra? ( mirror://sourceforge/${PN}/${PV}/${PN}-src-wip-cars-and-tracks-${PV}-r${REV}.tar.xz )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+addons extra profiling schedule_spy +trace +unload_ssggraph +xrandr"

RDEPEND="
	dev-games/freesolid
	media-libs/freeglut
	>=media-libs/libpng-1.2.40
	media-libs/libogg
	media-libs/libvorbis
	media-libs/openal
	media-libs/freealut
	media-libs/freetype
	net-misc/curl
	x11-libs/libX11
	x11-libs/libXxf86vm
	sys-libs/zlib
	virtual/glu
	virtual/opengl"
DEPEND="${RDEPEND}
	dev-libs/expat
	media-libs/libsdl2
	>=media-libs/plib-1.8.3
	net-libs/enet:1.3
	virtual/jpeg
	x11-proto/xproto
	x11-libs/libXext
	x11-libs/libICE
	x11-libs/libSM
	x11-libs/libXt
	x11-libs/libXi
	x11-libs/libXmu
	x11-libs/libXrender
	xrandr? ( x11-proto/randrproto )"

S=${WORKDIR}

src_unpack() {
	unpack ${PN}-src-base-${PV}-r${REV}.tar.xz
	use addons && unpack ${PN}-src-hq-cars-and-tracks-${PV}-r${REV}.tar.xz
	use addons && unpack ${PN}-src-more-hq-cars-and-tracks-${PV}-r${REV}.tar.xz
	use extra && unpack ${PN}-src-unmaintained-${PV}-r${REV}.tar.xz
	use extra && unpack ${PN}-src-wip-cars-and-tracks-${PV}-r${REV}.tar.xz
	if ( use !addons || use !extra ) ; then
		unpack ${PN}-src-partial-build-patch-2.0.0-r4687.tar.xz
	fi
}

src_configure() {

	local mycmakeargs=(
		$(cmake-utils_use profiling OPTION_PROFILER)
		$(cmake-utils_use schedule_spy OPTION_SCHEDULE_SPY)
		$(cmake-utils_use trace OPTION_TRACE)
		$(cmake-utils_use unload_ssggraph OPTION_UNLOAD_SSGGRAPH)
		$(cmake-utils_use xrandr OPTION_XRANDR)
		-DOPTION_OFFICIAL_ONLY=ON
		-DSD_BINDIR:PATH=$GAMES_BINDIR
		-DSD_DATADIR:PATH=$GAMES_DATADIR/speed-dreams-2
		-DSD_INCLUDEDIR:PATH=include/speed-dreams-2
		-DSD_LIBDIR:PATH=$(games_get_libdir)/speed-dreams-2
	)

	cmake-utils_src_configure
}
src_compile() {
	cmake-utils_src_compile
}

src_install() {
	cmake-utils_src_install

	# NOTE: We don't usually install INSTALL.txt, but I'm including it here because it
	# explains the unload_ssggraph option as a workaround for bugs in some setups.
	dodoc CHANGES.txt INSTALL.txt README.txt TODO.txt
	dohtml -r doc/faq doc/userman

	newicon -s scalable data/data/icons/icon.png ${PN}-2.svg
	make_desktop_entry "speed-dreams-2" "Speed Dreams" "${PN}-2"

	prepgamesdirs
}

#pkg_preinst() { games_pkg_preinst ; gnome2_icon_savelist ; }
#pkg_postinst() { games_pkg_postinst ; gnome2_icon_cache_update ; }
#pkg_postrm() { gnome2_icon_cache_update ; }