# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5
PYTHON_COMPAT=( python2_7 )
DISTUTILS_SINGLE_IMPL=1

inherit distutils-r1

DESCRIPTION="A lightweight streaming server which brings DLNA / UPNP and Chromecast support to PulseAudio and Linux"
HOMEPAGE="https://github.com/masmu/pulseaudio-dlna"
SRC_URI="https://github.com/masmu/${PN}/archive/${PV}.tar.gz -> ${PN}-${PV}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE=""
RESTRICT="mirror"

RDEPEND="dev-libs/protobuf[${PYTHON_USEDEP}]
	dev-python/beautifulsoup[${PYTHON_USEDEP}]
	dev-python/chardet[${PYTHON_USEDEP}]
	dev-python/docopt[${PYTHON_USEDEP}]
	dev-python/librsvg-python[${PYTHON_USEDEP}]
	dev-python/netifaces[${PYTHON_USEDEP}]
	dev-python/notify2[${PYTHON_USEDEP}]
	dev-python/psutil[${PYTHON_USEDEP}]
	dev-python/pycairo[${PYTHON_USEDEP}]
	dev-python/pygobject:3[${PYTHON_USEDEP}]
	dev-python/requests[${PYTHON_USEDEP}]
	dev-python/setproctitle[${PYTHON_USEDEP}]
	media-libs/faac
	media-libs/flac
	media-sound/lame
	media-sound/opus-tools
	media-sound/sox
	media-sound/vorbis-tools
	virtual/python-futures[${PYTHON_USEDEP}]"

DEPEND="${RDEPEND}
	dev-python/dbus-python[${PYTHON_USEDEP}]
	dev-python/pip[${PYTHON_USEDEP}]
	dev-python/setuptools[${PYTHON_USEDEP}]
	media-sound/pulseaudio"

src_install() {
	distutils-r1_src_install

	# Create pulseaudio-dlna.desktop file so that it may be XDG started on Xsession startup #
cat - > "${T}/${PN}.desktop" <<EOF
[Desktop Entry]
Name=Pulseaudio DLNA
Type=Application
Comment=A lightweight streaming server which brings DLNA / UPNP and Chromecast support to PulseAudio and Linux
Exec=pulseaudio-dlna --request-timeout=30
Terminal=false
Categories=
NoDisplay=true
StartupNotify=true
EOF
	insinto /usr/share/applications
	doins "${T}/${PN}.desktop"
	dosym /usr/share/applications/${PN}.desktop /etc/xdg/autostart/${PN}.desktop
}