opensc-0.16.0_pre1.ebuild

opensc-0.16.0_pre1.ebuild (text/plain), 1.54 KB, created by hexum on 2016-02-26 21:42:10 UTC

# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5

inherit eutils

if [[ ${PV} == "9999" ]] ; then
	EGIT_REPO_URI="https://github.com/OpenSC/OpenSC.git"
	inherit git-r3
else
	inherit versionator
	MY_PV="$(replace_version_separator 3 '-')"
	SRC_URI="https://github.com//OpenSC/OpenSC/archive/v${MY_PV}.zip -> ${P}.zip"
	S="${WORKDIR}/OpenSC-${MY_PV}"
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
fi

DESCRIPTION="Libraries and applications to access smartcards"
HOMEPAGE="https://github.com/OpenSC/OpenSC/wiki"

LICENSE="LGPL-2.1"
SLOT="0"
IUSE="doc +pcsc-lite secure-messaging openct ctapi readline ssl zlib"

RDEPEND="zlib? ( sys-libs/zlib )
	readline? ( sys-libs/readline:0= )
	ssl? ( dev-libs/openssl:0= )
	openct? ( >=dev-libs/openct-0.5.0 )
	pcsc-lite? ( >=sys-apps/pcsc-lite-1.3.0 )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	app-text/docbook-xsl-stylesheets
	dev-libs/libxslt"

REQUIRED_USE="
	pcsc-lite? ( !openct !ctapi )
	openct? ( !pcsc-lite !ctapi )
	ctapi? ( !pcsc-lite !openct )
	|| ( pcsc-lite openct ctapi )"

src_configure() {
	./bootstrap
	econf \
		--docdir="/usr/share/doc/${PF}" \
		--htmldir='$(docdir)/html' \
		--disable-static \
		$(use_enable doc) \
		$(use_enable openct) \
		$(use_enable readline) \
		$(use_enable zlib) \
		$(use_enable secure-messaging sm) \
		$(use_enable ssl openssl) \
		$(use_enable pcsc-lite pcsc) \
		$(use_enable openct) \
		$(use_enable ctapi)
}

src_install() {
	default
	find "${ED}"/usr -name '*.la' -delete
}