gnome-vfs-2.8.1-r1.ebuild

gnome-vfs-2.8.1-r1.ebuild (text/plain), 2.04 KB, created by Alexandre Rostovtsev (RETIRED) on 2004-10-26 21:54:06 UTC

# Copyright 1999-2004 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-vfs/gnome-vfs-2.8.1.ebuild,v 1.5 2004/10/18 16:30:21 foser Exp $

inherit gnome2 eutils

IUSE="doc ssl gnutls samba ipv6 hal howl"

SLOT="2"

DESCRIPTION="Gnome Virtual Filesystem"
HOMEPAGE="http://www.gnome.org/"

KEYWORDS="~x86"
LICENSE="GPL-2 LGPL-2"

RDEPEND=">=dev-libs/glib-2
	>=gnome-base/gconf-1.2
	>=gnome-base/orbit-2.9
	>=gnome-base/libbonobo-2
	>=dev-libs/libxml2-2.6
	app-arch/bzip2

	app-admin/fam

	gnome-base/gnome-mime-data
	>=x11-misc/shared-mime-info-0.14

	ssl? ( >=dev-libs/openssl-0.9.5
		!gnome-extra/gnome-vfs-sftp )
	gnutls? ( !ssl? ( net-libs/gnutls
			!gnome-extra/gnome-vfs-sftp ) )
	samba? ( >=net-fs/samba-3
		!gnome-extra/gnome-vfs-extras )
	hal? ( >=sys-apps/hal-0.2.92
		>=sys-apps/dbus-0.22 )
	howl? ( >=net-misc/howl-0.9.6-r1 )"

# FIXME : make the fam dep a virtual

# ssl/gnutls USE deps : if both are enabled choose openssl
# foser <[e-mail]> 19 Apr 2004

DEPEND="${RDEPEND}
	>=dev-util/intltool-0.29
	>=dev-util/pkgconfig-0.12.0
	doc? ( >=dev-util/gtk-doc-1 )"

G2CONF="${G2CONF} \
	$(use_enable ssl openssl) \
	$(use_enable gnutls) \
	$(use_enable samba) \
	$(use_enable ipv6) \
	$(use_enable hal) \
	$(use_enable howl) \
	--disable-schemas-install
	--without-gtk"

# this works because of the order of conifgure parsing
# so should always be behind the use_enable options
# foser <[e-mail] 19 Apr 2004
use gnutls && use ssl && G2CONF="${G2CONF} --disable-gnutls"

DOCS="AUTHORS COPYING* ChangeLog HACKING INSTALL NEWS README TODO"

src_unpack() {

	unpack ${A}
	cd ${S}

	# make howl a real switch (#64906)
	epatch ${FILESDIR}/${P}-howl_config.patch
	epatch ${FILESDIR}/${P}-locale_parsing.patch
	autoconf

}

src_install() {

	gnome2_src_install

	# remove unused dir (#46567)
	rmdir ${D}/usr/doc

	# FIXME: there are cleaner ways to do this
	echo "trash:    libvfolder-desktop" >> ${D}/etc/gnome-vfs-2.0/modules/default-modules.conf

}

# Fix bonobo 
USE_DESTDIR="1"